Chapter 10: Physics: Substances, Ropes, Energy and Weight
10.9. Heat

Since we prefer not to simulate burnt skin, and it is unsporting to kill a player outright merely for touching a hot object, heat is mostly used as a reason why something cannot be picked up at a given moment. This very basic puzzle is demonstrated in Grilling.

With the naked eye, it is not always easy to detect what is too hot to touch - a point made in both Masochism Deli, where the only solution is to keep picking up potatoes until one doesn't burn, and in Hot Glass Looks Like Cold Glass, where infrared goggles turn the scales.

If a hot object is not to be touched, will it stay hot forever? It might well, if it is a steak on an electric grill, but not if it is a recently-baked apple pie sitting on a window-sill. Entropy simulates the gradual return of temperature to equilibrium.

* See Electricity and Magnetism for items which shouldn't be touched because they are hot in a different way

* Example  Grilling
A grill, from which the player is not allowed to take anything lest he burn himself.

* Example  Masochism Deli
Multiple potatoes, with rules to make the player drop the hot potato first and pick it up last.

*** Example  Hot Glass Looks Like Cold Glass
Responding to references to a property that the player isn't yet allowed to mention (or when not to use "understand as a mistake").


Suppose we have a situation where the player is allowed to talk about the heat of an object only if he's properly equipped to detect it.

"Hot Glass Looks Like Cold Glass"

Heat is a kind of value. The heats are hot, warm, room temperature, or cold. A thing has a heat.

Understand the heat property as referring to a thing when the player wears the infrared goggles.

The Test Kitchen is a room. "Your own personal lab, ready for scrupulously scientific recipe research. You hope. The previous three runs of this did not go well." The pair of infrared goggles is carried by the player. The description is "A pair of head-mounted IR goggles which look very foolish when worn." The goggles are wearable.

A glass dish is a kind of container. A glass dish is transparent. Three room temperature glass dishes are on the counter. Two hot glass dishes are on the counter. Two cold glass dishes are on the counter. The counter is scenery in the Test Kitchen.

Instead of doing something other than examining to a hot glass dish:
    say "Ow! Crikey! You swear, and Claudia makes a sympathetic hiss. 'You're going to have a mark from that for sure,' she comments.";
    decrease the score by 2.

Instead of doing something when a hot glass dish is the second noun:
    say "You brush [the second noun], and wince, but manage to conceal that from Claudia.";
    decrement the score.

Before printing the name of a glass dish when the player wears the goggles: say "[heat] "

Before printing the plural name of a glass dish when the player wears the goggles: say "[heat] "

So far, so good. Now, what if the player tries to GET HOT DISH when the goggles are off? "You can't see any such thing." doesn't seem like quite the right response: he can see such a thing. He just doesn't know which it is.

We could go on to write a mistake rule that would scold the player for trying "get [heat] [text]" when not wearing the goggles. The problem is that this would not cover any other phrasing of the command, nor would it account for all the many other things the player might try to do with an object specified by heat.

What we really want is to catch all instances of the player using the property name when not allowed to do so; and for this purpose we can borrow a trick from the chapter on Activities:

After reading a command:
    if the player wears the goggles, make no decision;
    if the player's command includes "[heat]":
        say "Without the IR goggles on, you cannot tell hot things from cold at sight.";
        rule succeeds.

Claudia is a woman in the Test Kitchen. "Your assistant Claudia stands by with [a list of things carried by Claudia]." The description of Claudia is "Infinitely patient and a very good stenographer. She is studiously avoiding giving you any sort of look that might be construed as mocking." Claudia carries a notepad, a brined chicken breast, a blowtorch, and a cup of heavy cream.

Instead of asking Claudia for something which is carried by Claudia:
    move the second noun to the player;
    say "'Check, [second noun],' repeats Claudia, in the tone of one who has seen too many medical dramas. She does hand it over, though."

Instead of asking Claudia for something:
    say "She clears her throat faintly and glances at [the second noun], as though to say that it's not hers to give."

Test me with "get all / drop all / look / wear goggles / look / ask claudia for cream / put cream in hot dish / put cream in cold dish / remove goggles / get hot dish".

* Example  Entropy
All objects in the game have a heat, but if not kept insulated they will tend toward room temperature (and at a somewhat exaggerated rate).