When in Rome 1: Accounting for Taste — 24 of 31

Emily Short

Release 3

Section 3 - General adjustments to parsing

Report taking something:

say "You pick up [the noun][if the noun is heavy], though with a bit of effort[end if]." instead.

Report dropping something:

say "You set down [the noun]." instead.

Understand the command "wear" as something new. Understand "wear [something]" as wearing. Understand "wear [something wearable]" as wearing. Before wearing something which is not carried by the player: try taking the noun; if the noun is not carried by the player, stop the action.

Understand the command "give" as something new. Understand "give [something] to [something]" as giving it to. Understand "give [something] [something]" as giving it to (with nouns reversed).

Before giving something which is not held by the player to someone:

if the player wears the noun, try taking off the noun;

otherwise try taking the noun.

Before giving a person to an inanimate thing: try giving the second noun to the noun instead.

Understand the command "show" as something new. Understand "show [something] to [something]" as showing it to. Understand "show [something] [something]" as showing it to (with nouns reversed). Before showing something which is not held by the player to someone: try taking the noun. Before showing a person to an inanimate thing: try showing the second noun to the noun instead.

Understand the command "eat" as something new. Understand "eat [something]" as eating. Understand "eat [something edible]" as eating.

Before entering a closed container: try opening the noun; if the noun is closed, stop the action.