When in Rome 1: Accounting for Taste — 16 of 31

Emily Short

Release 3

Section 3 - Reports for the girl

Report the girl trying giving something to the creature:

if maximum action stack depth is greater than 0, say " reaches up";

otherwise say "Gingerly, the girl reaches up";

say " to hand ";

if the maximum action stack depth is greater than 0, say "it";

otherwise say "[the noun]";

say " to the visitor. You watch the transaction as well as you can, but since you can barely turn your head, you don't get much of a view." instead.

Report someone trying taking something when the action stack depth is greater than 0:

say "[The person asked]";

decrease the action stack depth by 1;

say " picks up [the noun][continue]";

stop the action.

Report the girl trying wearing the heels:

say "She slips the heels back on, adding a couple of inches to her already-considerable height." instead.

Report the girl trying searching something:

if the maximum action stack depth is greater than 0

begin;

say "[The person asked] looks inside. ";

end if;

if the noun contains something, say "'I see [a list of things in the noun] here,' she says. 'If that's any help.'" instead;

otherwise say "'Empty,' she reports tersely." instead.

Report the girl trying touching the creature:

if the creature is hostile, say "The girl reaches up to touch the creature, then jumps back when it growls. 'I don't think it's housebroken.'" instead;

otherwise say "The girl tries petting the creature, but this does not seem to calm it." instead.

Report the girl trying indicating something:

say "'It doesn't seem to be paying attention when I point at things.'"

Report the girl trying waving at something:

if the noun is the creature, say "'Hi!' she says, waving gamely at the creature. 'I don't think it speaks our language,' she concludes after a moment. 'It doesn't wave back.'";

otherwise say "'That isn't going to make things any better.'"

Report the girl trying examining the player:

say "'You do look a bit worse for wear,' she admits." instead.

Report the girl trying examining the girl:

say "'You should see yourself,' she replies dryly." instead.

Report the girl trying examining the handbag:

if maximum action stack depth is greater than 0, say "[The person asked] squints at [the noun]. ";

say "'It's your garden-variety tote,' she says. 'I don't think anything has happened to it since it left my possession.'" instead.

Report the girl trying examining the creature:

say "'It's... [the color of the creature],' she says. 'And it doesn't look like anything I've seen. I have the sense it's hungry. It keeps making biting faces at me.'" instead.

Report the girl trying taking the hot dog: [1]

if the maximum action stack depth is greater than 0, say "[The person asked] takes";

otherwise say "The girl picks up";

if the action stack depth is greater than 0

begin;

say "[The person asked]";

decrease the action stack depth by 1;

say " picks up the hot dog unenthusiastically[continue]";

stop the action;

otherwise;

say " [the hot dog] unenthusiastically. 'I hope you have a point here of some sort.'" instead;

end if.

Instead of girl trying taking the creature for the first time:

say "[The person asked] tries to prise off the grip of the thing, but the more she pulls on one arm, the more tightly it grips your throat with another, so that eventually she is forced to stop so that you don't get strangled."

Instead of the girl trying taking the creature more than once:

do nothing.

Instead of the girl trying attacking the creature:

now the girl is passive;

say "The girl pummels [the creature][if the girl carries the heels] with her shoes[end if] in the attempt to dislodge it.

It becomes more agitated[if the creature carries something], and tries hitting you with [a random thing carried by the creature][otherwise], squeezing your windpipe to the point of pain[end if]. 'Maybe that isn't a good idea,' you squeak."

Instead of asking the girl to try attacking the player:

now the girl is passive;

say "'I've heard of guys that are into that,' she says. 'Never met one before, though.'

Right. Well, it probably wouldn't have helped anyway."

Carry out the girl trying attacking something:

do nothing.

Report the girl trying attacking something:

say "The girl strikes [the noun], but to no effect."

Check the girl trying taking something (this is the no people lifting rule):

if the noun is the player, stop the action.

The trash can is in the Underpass. The trash can contains a half-eaten hot dog and a crumpled pamphlet. Understand "trashcan" as the trash can. The hot dog is edible. The pamphlet is papery. The trash can is fixed in place. Understand "food" as the hot dog. The trash can is openable and closed and transparent. The description of the pamphlet is "A Civil Defense pamphlet entitled [italic type]Atomic Blast Creates Fire[roman type]." Understand "civil defense" or "defense" or "atomic blast creates fire" as the pamphlet.

The trampled newspaper is a papery thing. It is in the Underpass. The description of the newspaper is "The 'Weather throughout the Nation' page, with a map of cold fronts across America. Unlikely that anyone will be needing this soon." Understand "weather section" or "paper" or "page" as the newspaper.

Report the girl trying examining the pamphlet for the first time:

say "'It's a Civil Defense pamphlet called [italic type]Atomic Blast Creates Fire[roman type],' she says, flipping through it. 'Good, Clean, Housekeeping Is Civil Defense Housekeeping,' she reads, in a radio-announcer voice. 'My mother sent me one of these.'" instead.

Report the girl trying examining the pamphlet for the first time:

say "'It's just an ordinary Civil Defense pamphlet. What to do when the bomb hits, that sort of thing.'"

A thing can be consumed or unconsumed. A thing is usually unconsumed. Carry out the creature trying eating something: now the noun is consumed.

Satiety is a scene. Satiety begins when Getting handbag is happening and at least three things are consumed. When Satiety begins: remove the creature from play; say "At last the creature's grip on you slackens, and it relaxes and slides to the ground, almost immediately asleep.

'How bizarre,' says the girl, approaching it and reaching out as though she wants to touch it.

'Don't wake it,' you say, standing over it. 'Go call for animal control or the police. I'll make sure it doesn't go anywhere. Or try to, anyway.'";

make scene break.

Satiety ends when the time since Satiety began is 1 minute.

Instead of doing something in the Underpass:

if looking or examining, continue the action;

if dropping, continue the action;

if asking someone to try doing something, continue the action;

if asking someone about something or telling someone about something, continue the action;

if asking someone about specified object something, continue the action;

if asking someone for help, continue the action;

if asking someone for something, continue the action;

if asking someone for vague help, continue the action;

if answering a person that something, continue the action;

if waiting, continue the action;

say "[if a random chance of 1 in 2 succeeds]You try, but the more you struggle, the tighter the creature holds[otherwise]Your arms are pinned by the creature on your back and shoulders, which prevents you from being much use[end if]."

Understand "talk to [someone]" as a mistake ("You can ASK someone ABOUT something, ASK someone FOR something, or ASK someone TO DO something.").

Understand "breathe" or "inhale" or "exhale" as a mistake ("You are still able to get some breath, yes.").

Instead of asking someone for something, try asking the noun to try giving the second noun to the player.

Instead of waiting in the presence of the creature when Getting handbag is happening:

say "You try holding very still, the way snake victims are supposed to. Perhaps your tormentor will think you have died and lose interest in twisting your head off, which seems to be its current obsession."

Before taking inventory when Getting handbag is happening:

say "You can hardly go through your pockets while pinned like this, though in fact you doubt you have anything useful anyway." instead.

A person has a table-name called conversation. The conversation of the girl is the Table of Girl Conversation.

Instead of asking someone about something:

let the source be the conversation of the noun;

if topic understood is a topic listed in source

begin;

if there is a turn stamp entry

begin;

say "[The noun] has already told you [summary entry].";

otherwise;

change turn stamp entry to the turn count;

say "[reply entry][paragraph break]";

end if;

otherwise;

say "[The noun] stares at you blankly.";

end if.

Definition: a person is other if it is not the player.

Understand "ask [someone] about [something]" as asking it about specified object. Understand "tell [someone] about [something]" as asking it about specified object. Asking it about specified object is an action applying to two visible things. Carry out asking it about specified object: say "[The noun] just shrug[s]." Asking something about specified object something is useless action.

Instead of asking the girl about specified object something: try the girl trying examining the second noun.

Understand "recap" or "recall" or "review" as recalling conversations.

Recalling conversations is an action applying to nothing. Recalling conversations is useless action. [2]

Carry out recalling conversations:

repeat with speaker running through other people

begin;

let source be the conversation of the speaker;

sort source in turn stamp order;

say "[The speaker] has so far told you: [line break]";

let index be 0;

repeat through source

begin;

if there is a turn stamp entry

begin;

let index be 1;

say " [summary entry][line break]";

end if;

end repeat;

if index is 0, say " absolutely nothing[line break]";

say line break;

end repeat.

Table of Girl Conversation

topicreplysummaryturn stamp
"animal/creature/dog/critter/beast""'Any second thoughts on what this is?' you ask.

'I thought it was a dog, but that was earlier when it was biting my dress,' she says. 'It could be anything. Or rather, it couldn't be anything: I don't think I've ever heard of an animal like it. Maybe it's from Mars.'

You chuckle, but with less conviction than you'd like."
"that she really has no notion what the animal is"a number
"Mars/aliens/planets/planet/alien/extraterrestrial/venus/mercury/jupiter/moon/luna/saturn/uranus/neptune/pluto""'Do you believe in life on other planets?'

'If I'm meeting it now, yes.'"
"that she might be convinced there is life on other planets"--
"weather""'How's the weather?'

'It's fine, and is this getting us anywhere?'"
"that the weather continues fine, and that this has nothing to do with anything"--
"girl/herself""'Tell me about yourself,' you say.

'This is hardly the time for introductions!' she replies.

'I don't seem to be going anywhere,' you point out."
"that this isn't the time for introductions"--
"me/myself""'Let me introduce myself,' you say.

'No, don't,' she says. 'If the thing kills you, I want you to remain just some stranger.'

'Oh, that's very thoughtful! So if we were introduced, you'd be making more of an effort to free me?'

'I'm thinking!' she replies.

You are both stubbornly silent for a moment."
"that she doesn't want to be introduced just yet"--
"job/employment/work" or "her job/employment/work""'What do you do during the day?'

'Clipping service,' she says curtly. 'But I'm looking for a new place.'

'Don't like it?'

'The boss is a bit clingy,' she says.

'I know how that feels,' you say, trying to reposition the critter's grip on you so that you can breathe a little more freely."
"that she works for a clipping service but is planning to leave"--
"clipping service""'What do you do at a clipping service, anyway?'

'Clip articles out of the paper,' she says, looking surprised. 'Any news about any of our clients.'

'Ah.' You refrain from saying how dull this sounds. She probably wouldn't find your work at the bank very exciting either."
"that a clipping service sends clippings to people"--
"boss/employer" or "office romance""'I take it that you don't have any dime-store novel ideas about marrying your boss?'

'He's already married,' she says curtly. 'He just likes to wander.'

'Ah.'"
"that her boss is a philanderer"--
"Korea/italy/war/soldiers/soldier/fighting/army/sergeant""You start to make an observation about your life in the Army, but this meets with a stopping glare from the cool eyes, so that -- though you can think of no particular reason why -- you feel you have made a blunder, and fall silent.""that she doesn't want to discuss the war"--

Understand "ask [someone] for [police]" as asking it for help. Asking it for help is an action applying to one thing. Carry out asking it for help: try asking the noun to try getting help.

Instead of answering someone that "[help]", try asking the noun for vague help.

Understand "ask [someone] for [help]" or "ask [someone] to [help]" as asking it for vague help. Asking it for vague help is an action applying to one thing. Carry out asking it for vague help: say "[The noun] looks confused." Instead of asking the girl for vague help: say "'I'm trying! But I don't want to leave you here, and I also don't quite see how to get it off you...'"

Instead of asking the girl about "[police]": try asking the girl to try getting help.

Understand "siren/sirens/police/policemen/policeman/fireman/firemen/emergency" or "fire/police department/help" as "[police]". Understand "help" or "assist" or "aid" or "help me" or "assist me" or "aid me" as "[help]".

Understand "fetch [police]" or "summon [police]" or "get [police]" or "call [police]" as getting help. Getting help is an action applying to nothing.

Carry out the girl trying getting help: do nothing.

Report the girl trying getting help: say "'Okay,' you say. 'I have an idea. I will stay here with our rabid lunatic friend, since I have no choice, while you will go and fetch some kind of animal control personnel, or possibly a policeman or fireman. As quickly as possible, please.'

She brightens at this suggestion. 'Yes, of course, I'm sorry. Stupid of me.' [if the girl wears the heels]She takes off the heels again and[otherwise]Still stocking-footed, she[end if] heads back up the pathway briskly.

Even so, it's an unpleasantly long wait until some animal-catchers arrive, suited up in protective suits, and shoot the creature with a tranquillizing dart. But you are free of it at last."; remove the creature from play.

Carry out getting help: say "Not likely to be much use just at the moment."

Notes

[1]. The 'action stack depth' allows for actions that can happen implicitly to be stacked together into a single sentence.

[2]. When we define any new action that we don't want to allow the character to do, we need to set it accordingly (because our persuasion rules are so open-ended).