When in Rome 1: Accounting for Taste — 15 of 31

Emily Short

Release 3

Section 2 - Persuasion and obedience

Check the girl trying taking off the dress (this is the can't take off dress rule): if the person asked wears the noun, stop the action.

Check the girl trying taking something worn by the player (this is the can't take your clothes rule): stop the action.

A persuasion rule for asking Esther to try doing something: say "She gives you a mildly exasperated look, as though to say that she does not take instructions merely because they are issued by men."; rule fails.

A persuasion rule for asking the girl to try doing something: persuasion succeeds.

Instead of asking someone to try kissing the player: try kissing the person asked.

Unsuccessful attempt by girl trying doing something:

repeat through table of Esther Retorts

begin;

if the reason the action failed is the cause entry

begin;

say "[response entry][paragraph break]";

rule succeeds;

end if;

end repeat;

say "'[if a random chance of 1 in 2 succeeds]Nope[otherwise]No[end if], [if a random chance of 1 in 2 succeeds]I don't think that's going to work[otherwise]that's not possible[end if],' the girl says."

Report the girl trying taking inventory:

if the number of things carried by the girl is 0

begin;

say "She spreads her hands: not carrying a thing." instead;

otherwise;

if the number of things carried by the girl is 1, say "'Just this,' she says, indicating [the list of things carried by the girl]." instead;

otherwise say "She holds up [the list of things carried by the girl] so you can see." instead;

end if.

Contact relates a thing (called X) to a thing (called Y) when X is part of Y or Y is part of X. The verb to be joined to implies the contact relation.

Table of Esther Retorts

causeresponse
can't take yourself rule"'I think I'd need the power of levitation in order to do that,' the girl says."
can't take other people rule"'I don't know what manners they teach where you come from, but back in Ohio it was thought impolite to pick people up without their permission,' the girl remarks."
can't take component parts rule"'[The noun] [is-are] pretty well attached to [a random thing which is joined to the noun],' the girl remarks."
can't take people's possessions rule"'Just snatching it from [a random person who holds the noun]? That doesn't seem polite.'"
can't take what you're inside rule"'From inside?' the girl demands."
can't take what's already taken rule"[already done]"
can't take scenery rule"'I don't think I have quite the lifting power,' the girl says. 'Though I'd enjoy watching you try.'"
can't take what's fixed in place rule"'I don't think I have quite the lifting power,' the girl says. 'Though I'd enjoy watching you try.'"
can't exceed carrying capacity rule"She holds up her hands. 'I'm already full up, here.'"
can't insert into closed containers rule"[physical impossibility]"
can't go that way rule"[physical impossibility]"
can't go through closed doors rule"[physical impossibility]"
can't enter closed containers rule"[physical impossibility]"
can't exit closed containers rule"[physical impossibility]"
can't drop yourself rule"[physical impossibility]"
can't drop what's already dropped rule"[already done]"
can't drop what's not held rule"'[The noun] [is-are] already not in my possession,' replies the girl."
can't drop clothes being worn rule"[salacious retort]"
can't take your clothes rule"[salacious retort]"
can't take off dress rule"[salacious retort]"
can't put something on itself rule"[physical impossibility]"
can't put onto something being carried rule"'I don't quite see how,' she says."
can't put onto what's not a supporter rule"'That's more of a balancing act than I'm up for, I'm afraid,' she says."
can't put clothes being worn rule"[salacious retort]"
can't insert clothes being worn rule"[salacious retort]"
can't wear what's not clothing rule"'They say men are oblivious to fashions, but you exceed the normal, don't you?'"
can't wear what's already worn rule"[already done]"
can't eat unless edible rule"'Unlike some critters I could mention, I do not have a cast iron stomach,' she says."
can't eat clothing without removing it first rule"[salacious retort]"
can't take off what's not worn rule"[already done]"
can't close what's already closed rule"[already done]"
can't open what's already open rule"[already done]"
can't switch off what's already off rule"[already done]"
can't switch on what's already on rule"[already done]"
can't unlock what's already unlocked rule"[already done]"
can't lock what's already locked rule"[already done]"
no people lifting rule"'A human pyramid doesn't seem like the solution to our problems,' she observes."
no repeat refuse rule"'Oh, I think not,' she says. 'I don't feel like having it throw [the noun] at my head again.'"

Before asking the girl to try going nowhere:

say "'I'm not leaving you here by yourself,' she says. 'It could kill you.'" instead.

Rule for supplying a missing noun while going:

change noun to outside.

Procedural rule: ignore the block vaguely going rule.

To say already done:

repeat through Table of Esther's Bored Remarks

begin;

say "[response entry]";

blank out the whole row;

rule succeeds;

end repeat;

say "'Already done.'"

Table of Esther's Bored Remarks

response
"'That's already taken care of,' she says."
"'I don't think that's necessary, under the circumstances.'"
"'We don't need to do that.'"
"It's done.'"

To say salacious retort:

repeat through Table of Esther's Flirtatious Remarks

begin;

say "[response entry]";

blank out the whole row;

rule succeeds;

end repeat;

say "She pretends not to hear."

Table of Esther's Flirtatious Remarks

response
"She looks at you sharply. 'If that was supposed to be cute, I warn you, I don't have much patience.'"
"She sniffs."

To say physical impossibility:

repeat through Table of Esther's Frustrated Denials

begin;

say "[response entry]";

blank out the whole row;

rule succeeds;

end repeat;

say "The girl rolls her eyes."

Table of Esther's Frustrated Denials

response
"'Is the lack of oxygen going to your head?' she asks, bewildered by this impossible instruction."
"'I know, you're into Eastern philosophy. Cut an Ohio girl a break, huh?'"
"The girl taps her foot."
"She purses her lips. 'I'm glad to help if I can, but we're going to have to stick to the realm of the remotely logical.'"

Procedural rule: ignore the block giving rule; ignore the block showing rule; ignore the block smelling rule; ignore the block listening rule.

Carry out listening to something:

do nothing.

Report listening to something: say "Your attention bears no interesting result."

Report listening to a room: say "There's no one thing that sounds notable here." instead.

Carry out smelling something:

do nothing.

Report smelling something: say "Your attention bears no interesting result."

Report smelling a room: if a stinky thing is in the location, say "You catch a whiff of [the list of stinky things in the location]." instead; otherwise say "Nothing stands out."

Report someone trying listening to something: say "[The person asked] concentrates, listening."

Report someone trying smelling something: say "[The person asked] sniffs at [the noun]."

Instead of asking someone for something: try asking the noun to try giving the second noun to the player.

Carry out showing something to someone: say "You reveal [the noun] to [the second noun]."

Carry out the girl trying showing something to someone:

if the second noun is the player

begin;

if the noun is fixed in place

begin;

say "The girl poses, model-like, next to [the noun], but this naturally doesn't tell you much more than you knew before.";

otherwise;

say "The girl shows you [the noun]. [run paragraph on]";

try examining the noun;

end if;

otherwise;

say "The girl reveals [the noun] to [the second noun].";

end if.

Instead of asking someone to try saying yes: try saying yes. Instead of asking someone to try saying no: try saying no. Instead of asking someone to try saying sorry, try saying sorry. Instead of asking someone to try swearing obscenely, try swearing obscenely. Instead of asking someone to try swearing mildly, try swearing mildly.

Singing is useless action. Burning something is useless action. Waking up is useless action. Thinking is useless action. Cutting is useless action. Jumping is useless action. Tying something to something is useless action. Drinking something is useless action. Swinging is useless action. Rubbing is useless action. Setting something to something is useless action. Waving hands is useless action. Buying is useless action. Climbing is useless action. Sleeping is useless action. Kissing is useless action. [Throwing something at something is useless action.] Asking something about something is useless action. Telling something about something is useless action. Answering something that something is useless action. Waking something is useless action. Orienting something toward something is useless action.

Instead of asking girl to try useless action:

say "The girl frowns. 'I don't see how that would help in the current situation.'".