The Reliques of Tolti-Aph — 11 of 57

Graham Nelson

Release 1

Section 2(c) - Staffs, strength potions and scrolls

After examining something made of magic-imbued wood, say "Holding [the noun] reduces the strength cost of any spell by 2."

After printing the name of something made of magic-imbued wood while taking inventory: say " (magic-imbued)".

To decide which number is the strength cost of (incantation - a spell) to (wizard - a person):

let the damage be the cost of the incantation;

if the wizard is carrying something made of magic-imbued wood, decrease the damage by 2;

if the damage is less than zero, let the damage be zero;

decide on the damage.[1]

A strength potion is a kind of thing. A strength potion has a die roll called additional strength. Instead of examining a strength potion, say "[The noun] is a [additional strength] strength potion." A strength potion is usually sustenance.

Instead of eating or drinking a strength potion:

remove the noun from play;

say "You swallow [the noun], gaining ";

let the extra be the roll of the additional strength of the noun;

increase the strength of the player by the extra;

if the strength of the player is greater than the permanent strength of the player:

change the strength of the player to the permanent strength of the player;

say " - more than enough to restore you to full strength.";

stop;

say " strength points."

A scroll is a kind of thing. A scroll has a spell called the inscribed spell. A scroll is paper. The description of a scroll is "Careful to take only a glance, you see that [the item described] is inscribed with the runes of the [inscribed spell] spell." After printing the name of a scroll while taking inventory: say " (bearing the [inscribed spell] spell)".[2]

Notes

[1]. This phrase calculates the actual strength cost to a given person of casting a given spell, and as we see this cost is reduced if the person is carrying a "magic staff"-like item.

[2]. Scrolls will be the player's objects of desire, since they carry new spells to be memorised and added to the player's current repertoire.