Section W(e) - The Garret and the Archivist
The hole is an open unopenable door. It is scenery. Understand "opening" as the hole. It is above the Knotted Room and below the Dim Garret. The printed name of Dim Garret is "[if archivist is lit and archivist is in location]Brilliant[otherwise]Dim[end if] Garret".
Instead of searching the hole in the Garret:
say "You look down into the room below, hoping your makeshift ladder will hold up for the return trip."
Instead of searching the hole in the Knotted Room:
if a lit thing is in the Garret, say "White light and odd shadows are visible through the hole, but you can make out no more than that.";
otherwise say "It looks dark up there."
The description of the Dim Garret is "A round room[if the archivist is in location and archivist is lit], dirty with age[otherwise], very badly lit[end if], with a hole in the floor giving onto the room below." The line of cubbyholes is fixed in place in the Dim Garret. "[if fixed in place]Empty cubbyholes, made of decaying wood, line the walls: these might once have held strands of varying thickness and colour[otherwise]On the ground is a sort of box made of rotten wood[end if]." It is a container. Understand "cubbyhole" or "holes" or "nook" or "niche" or "niches" or "nooks" or "box" or "decaying" or "lidless" as the cubbyholes. The line of cubbyholes is wood.
Instead of attacking the fixed in place cubbyholes: now the line of cubbyholes is portable; change the printed name of the cubbyholes to "box of rotten wood"; say "You smash the cubbyholes, which come away from the wall in fragments, leaving you with a sort of detached, lidless box made of rotten wood."
Instead of attacking the portable cubbyholes: say "Haven't you done enough?"
Instead of casting mend at the portable cubbyholes when the cubbyholes are not in the location:
say "To mend properly, they'd have to be set down in the room, since they reassemble into furniture."
Effect of casting mend at the portable cubbyholes:
now the line of cubbyholes is fixed in place;
change the printed name of the cubbyholes to "line of cubbyholes";
record outcome "reassembling a rickety but functional container";
The archivist is a priest in the Dim Garret. He is indifferent. The archivist can be active or passive. "Crouched in the center of the room, surrounded by filaments of various weights and colours, is an archivist[if lit]. He glows with magelight[end if]." The description is "He is very thin, as though he has been preserved by drying, and wears small round spectacles[if lit]. He also glows with a flickering white light[end if]."
Instead of going to the Garret when the player knows magelight and the archivist is unlit for the first time:
say "You hesitate - after all, the old lunatic has probably gone out like a snuffed lamp by now, and if you head up there you may be required to re-light him."
Instead of attacking the archivist: say "You swing at him, but make no contact. 'Ah,' he says, 'you have come far too late to kill me, I fear.'"
Instead of going to a room in the presence of the unlit archivist when the player knows magelight:
say "The archivist stops you with a sign that ripples in the air[if the archivist is affected by silence]. Apparently you will not be allowed to depart until you have done your part[otherwise]. 'Not until you have given me light - such was our compact,' he says[end if]."
repeat through the Table of Enchantments:
if the duration timer entry < 1, now the archivist is not affected by the spell entry;
if the archivist is not affected by magelight, now the archivist is unlit.
Report casting in the presence of the archivist:
say "As you intone the words of the [spell understood] spell, ";
if the current spell focus is something:
say "[the current spell focus] ";
unless the player is holding the current spell focus, say "vanishes as it ";
say "releases ";
say "your fingers release ";
say emission of the spell understood;
unless the second noun is a room, say " at [the second noun]";
say ", [current spell outcome]";
if the archivist is affected by the spell understood:
if duration of the spell understood is greater than 0:
say ", which will last for [duration of the spell understood in words] turn[s]";
change the duration timer of the spell understood to the duration of the spell understood;
increase the duration timer of the spell understood by 1;
consider the current spell event;
now the archivist is passive;
stop the action.
Effect of casting mindsift at the archivist:
record outcome "but his eyes rise to meet your gaze. [if archivist is affected by silence]He smiles and shakes his head, and you know that you have just involuntarily given him a glimpse of your own history[otherwise]He smiles. 'I wouldn't,' he warns you, in the dialect of your own hometown[end if]";
Effect of casting web at the archivist:
record outcome "but the strands wrap your own arms, pinning you in place, and then dissolve again with a gesture from the priest";
Effect of casting magic missile at the archivist:
record outcome "but the fire turns and threatens to engulf you instead. Only at the last moment a motion from him diverts it";
Effect of casting mend at the archivist:
restore the health of the player;
record outcome "but the spell reflects at you, restoring your strength instead. [if archivist is affected by silence]The archivist's mouth opens in laughter you cannot hear[otherwise]The archivist laughs, a bright and pleased chuckle. 'You have promise. Almost I wish I could still take an apprentice,' he remarks[end if]";
Effect of casting silence at in the presence of the archivist:
record outcome "settling around the archivist, who makes a comment you are unable to hear";
now the archivist is affected by silence;
Effect of casting aerial shield at in the presence of the archivist:
now the archivist is affected by aerial shield;
record outcome "creating a shield of protection above the archivist";
Effect of casting magelight at in the presence of the archivist:
now the archivist is affected by magelight;
now the archivist is lit;
record outcome "settling on the archivist";
Effect of casting cure baldness at the archivist:
record outcome "but the spell rebounds on you. [if archivist is affected by silence]The archivist smirks silently[otherwise]'If I may venture an opinion informed by fashion many centuries past - the curls are unbecoming,' the archivist remarks[end if]";
Instead of casting memorise at in the presence of the archivist:
say "The archivist holds up a hand[if the archivist is affected by silence]. He points at his own forehead warningly[otherwise]. 'Don't, unless you wish me to be the one to learn the spell,' he warns[end if]."
Instead of giving something to the archivist:
say "You hold out [the noun], but when the archivist reaches out his fingers pass through yours without even the chill that comes of touching a ghost."
Instead of showing a display listed in the Table of Archivist Reactions to the archivist:
if the archivist is affected by silence, say "He shrugs, pointing to his silenced mouth.";
say "[reaction entry][paragraph break]".
Instead of showing or giving the much-knotted string to the archivist:
remove the much-knotted string from play;
now the player knows magelight;
say "The archivist leans close, murmuring to himself as he interprets the spell and commits it to memory - to your memory, that is."
The much-knotted string is a thing. The description is "At a guess, it is the equivalent of a spell scroll, holding some incantation of light."
Table of Archivist Reactions
|stretched scroll||"He reads it over through the spectacles. 'Not entirely purposeless, I think,' he remarks."|
|blank parchment||"'I am surprised no one has yet written on such a promising surface,' he says."|
|cursive diary||"'Ah, pity,' he says. 'She had courage, but courage alone does not always suffice.'"|
if the player can see the archivist and the archivist is active:
if the archivist is affected by silence:
say "The archivist keeps working, but you cannot hear a move he makes.";
if the archivist is lit:
say "The archivist works swiftly over his threads, comparing colours.";
repeat through Table of Archivist Chatter:
say "[reaction entry][paragraph break]";
blank out the whole row;
stop the action;
say "The archivist's fingers move briskly over the strands, knotting here and there.";
now the archivist is active.
Instead of asking the archivist about a topic listed in the Table of Archivist Chatter:
if the archivist is affected by silence, say "He points at his silenced throat." instead;
now the archivist is passive;
say "[reaction entry][paragraph break]";
blank out the whole row.
Instead of asking the archivist about something, say "'What? what? Oh, you talk nothing but nonsense,' says the archivist."
Instead of answering the archivist that something: try asking the archivist about it. Instead of telling the Archivist about something: try asking the archivist about it.
Table of Archivist Chatter
|"hello/hi/hey"||"'You again,' remarks the archivist, without looking at you. 'Or is this your first time? No matter.'"|
|"time/age/temporal/reflection"||"'The time spell takes all my strength,' he says. 'I maintain it, it maintains me, nothing left over.'"|
|"time spell/spell/time/scroll/temporal/age/infinity/infinite/eternity"||"The archivist holds up a peculiar scroll, twisted and stitched top to bottom so that it has no end or beginning, but as you reach out to touch it your fingers slip through. He tucks the scroll back inside his clothing. [paragraph break]'Not for you,' he says. 'It allows doing things and undoing them, going forward, going back... Such spells are not intended for us to discover, I think.'[paragraph break]Then he frowns, seeming to regret this revelation. There is a sticky sort of POP in the air around your head, and you forget -"|
|"task/job/knots/knot/work/threads/thread/rope/ropes/archive/archives"||"'You know,' says the archivist, glancing at you over the top of his spectacles. 'This task would be easier with a bit of light. The threads have colours as well as knots.'"|
|"meaning/purpose/subject/thread/threads/rope/ropes/knots/knot/archive/archives"||"'All day and night counting and comparing,' he mutters, perhaps to you or perhaps to himself. 'Comparing and counting. Oh, sometimes I go out and practice a little archery, I suppose. D'you know, a good high arrow from here can even reach the old Longwall turret? But counting! That's the thing.'"|
|"light/lights/light spell"||"'I'd perform the light spell myself, but I haven't the strength, nor the wood either.'"|
|"light/lights/light spell"||"'You could do it, of course,' he says. 'Learn the light spell, cast it for me. You could keep it afterwards, if you wanted. In your head. A payment in your mind, what think you?' He tilts his head this way and that, like a bird. 'Yes?'"|
|"light/lights/light spell/payment/learning/memorizing/memorising/casting"||"He selects a new strand and begins knotting it carefully, counting, muttering. You cannot hear the words. [string placement] "|
|"darkness/dark"||"[if archivist is lit]He smiles. [otherwise]He works, squinting down at the strands and cursing the darkness. [end if]"|
|"help/assistance"||"[if archivist is lit]'Don't think I'm not grateful,' he says. 'But I must work now while the spell holds.' [otherwise]'You could help if you wanted to,' he says, 'but if not, I wish you'd go away.' He follows this with a sharp glance. [end if]"|
|"plaster/water/goddess"||"[if archivist is lit]'I do not know whether the goddess yet lives,' he says. 'Perhaps she has only moved away.' [otherwise]The archivist squints over his thread, muttering: 'Water as a liquid? or the goddess herself? Difficult to say without the colours... Would you say this was blue? or green? No, you won't be able to tell any better than I.' [end if]"|
|"plaster/water/goddess/blue/green"||"[if archivist is lit]'Grey-green is her colour, if you want to find the goddess in the strands.' But of course you wouldn't be able to make any sense of them anyway. [otherwise]'They should have put a lamp in here with me,' says the archivist. 'I told them - bad arrangement - temple bureaucrats were never very wise.' [end if]"|
|"smart/arrangement/bureaucrats/temple"||"'This was a bustling place once,' he says. 'You wouldn't believe... they're all gone now, of course, of course. Demanding tribute is a dangerous business to get into.'"|
|"tribute"||"'Folk get testy when their wells run dry,' he comments, counting. 'Apt to place blame - four, five, that's a drought for certain, and not just a dry spell.' He holds up the offending strand for you to see, but you make no more of its five-knot-row than he just told you."|
|"snake/snakes/copper-scaled snake"||"'Shrinks year by year as its curse works out,' he remarks, to the air. 'It won't be much more than a grub when the spell ends. I could look - but I don't like to go that far ahead.'"|
To say string placement:
if cubbyholes are fixed in place and cubbyholes are in location:
say "Then he rises and tucks the strand into one of the cubbyholes; and the moment his hand leaves it, it grows old and dry and brittle as though it has been lying there for centuries. ";
move much-knotted string to cubbyholes;
say "Then he rises and lays the string a few feet from himself; and when his hand leaves it, it grows old and dry and brittle as though it has been lying there for centuries. ";
move much-knotted string to location.