The Reliques of Tolti-Aph — 13 of 57

Graham Nelson

Release 1

Section 2(e) - Effect of standard spells in alphabetical order

Effect of casting aerial shield at:

record outcome "and forms an almost invisible saucer-like shield over your head, which moves with you";

now the player is affected by aerial shield;

rule succeeds.

A thing can be trapped or untrapped. A thing is usually not trapped.

Instead of drinking a trapped strength potion:

remove the noun from play;

say "You quaff [the noun], but it is poison! And it harms you by ";

let the extra be the roll of the additional strength of the noun;

decrease the strength of the player by the extra;

say " strength points.";

if the player is killed, end the game saying "You have been poisoned".

Instead of putting a trapped strength potion on a weapon:[1]

remove the noun from play;

let the hit power be the hit dice of the second noun;

let N be the dice part of the hit power;

let S be the sides part of the hit power;

let A be the adds part of the hit power;

increase A by 2;

increase N by 1;

change the hit dice of the second noun to the die roll with dice part N sides part S adds part A;

say "Carefully, you apply the poison from [the noun] to [the second noun], using it all up."

Understand "poison [something]" as a mistake ("How, exactly?").

A person can be slumbering or wakeful.

Effect of casting dragon sleep at a wyvern:

if the second noun is wakeful:

record outcome "and quite beguiles the wyvern which, though not properly speaking a dragon, is always flattered by any suggestion that it counts as one in the great scheme of things. Enormous snores soon result";

award 4 points;

now the second noun is slumbering;

otherwise:

record outcome "but, after all, the wyvern is already asleep";

rule succeeds.

Instead of doing something to a slumbering wyvern, say "Best let sleeping wyverns lie."

Effect of casting detect trap at:

if a trapped thing is visible:

record outcome "and it swirls around you for a time before finally settling upon [the list of trapped visible things]. You give a grim smile";

otherwise:

record outcome "but it radiates away with a sense of calm normality";

rule succeeds.

Effect of casting fashion staff at:

now the current spell focus is magic-imbued wood;

record outcome "growing scorch-hot in your hands as the wood is transformed into a magical hybrid, imbuing it with strength";

rule succeeds.

Effect of casting inner warmth at:

record outcome "and surrounds you with a cosy feeling of well-being";

now the player is affected by inner warmth;

rule succeeds.

Effect of casting ironbones at:

record outcome "and fortifies your whole body";

now the player is affected by ironbones;

rule succeeds.

Effect of casting know nature at:

if the second noun is a direction, record outcome "never to return";

otherwise record outcome "which make a curious sort of examination and then trace the sigil of [material of the second noun] in mid-air";

rule succeeds.

Effect of casting magelight at:

record outcome "which bathe your upper body in radiance";

now the player is affected by magelight;

now the player is lit;

rule succeeds.

Every turn: unless the player is affected by magelight, now the player is unlit.

Effect of casting magic missile at something:

if the second noun is a person:

record outcome "bursting in a splash of magical fire";

record event the magic missile strike rule;

otherwise:

if the second noun is portable and the second noun is not scenery:

remove the second noun from play;

record outcome "which vapourises into a whiff of smoke";

otherwise:

record outcome "which shakes as it absorbs the blow, but withstands it";

rule succeeds.

This is the magic missile strike rule:

say "A magic missile does 1d6 damage per level of the caster, so: ";

let L be the level of the player;

let the strike power be the die roll with dice part L sides part 6 adds part 0;

let the strike amount be the roll of the strike power;

say " points of damage";

now the second noun is hostile;

make the second noun take the strike amount points of damage.

Sanctum Sanctorum is a room. "Here in the calm, still centre of the turning world, you find Sanctuary. It is a place to rest, to meditate. Through the hazy rainbow walls, you can vaguely see the [room outside from the Sanctum Sanctorum], but it is as unreal as a dream." Before going outside from the Sanctum Sanctorum, say "You blink as your eyes adjust to the harshness of reality - the unforgiving vividness of existence."

The rainbow outlines of your sanctuary are fixed in place. "Before you are the rainbow outlines of your sanctuary, which you alone can see, never mind enter." Instead of entering the rainbow outlines: move the player to the Sanctum Sanctorum. Understand "sanctum" as the rainbow outlines.

Understand the command "rest" as "sleep". Understand the command "dream" as "sleep". Understand the command "meditate" as "sleep". Check sleeping (this is the can't sleep outside of sanctuary rule): if the location is not the Sanctum Sanctorum and the location is not the Temple of Peace, say "This is not a safe enough place to recuperate. Nowhere exposed to attack is ever safe." instead. Check sleeping: if the strength of the player is the permanent strength of the player, say "You are hale and hearty, with no need of rest." instead.

Carry out sleeping: restore the health of the player. Report sleeping: say "You rest, soaking up the healing goodness of the sanctuary." Procedural rule: ignore the block sleeping rule.

Check saving the game: if the location is not the Sanctum Sanctorum and the location is not the Temple of Peace, say "(The game can only be saved when in an indisputably safe place. This is not that place. You will know it when you find it.)" instead.[2]

Effect of casting make sanctuary at:

if the location is the Sanctum Sanctorum:

record outcome "which - thankfully - dissipate harmlessly. There probably are necromancers in this world who could get away with a stunt like that, but you're not one of them.";

rule succeeds;

record outcome "which - sketchily at first, but with growing confidence of purpose - come together into the ghostly rainbow outlines of a sanctuary before you";

change the outside exit of the Sanctum Sanctorum to the location;

move the rainbow outlines of your sanctuary to the location;

rule succeeds.

Effect of casting memorise at something:

record outcome "which fades and recovers itself, in a curiously unsatisfying way";

rule succeeds.

Effect of casting memorise at a scroll:

unless the player is carrying the second noun:

record outcome "which, not being in your hands, tantalises more than it reveals";

rule succeeds;

remove the second noun from play;

now the player knows the inscribed spell of the second noun;

record outcome "which crumbles into dust, filling your mind with thoughts of the [inscribed spell of the second noun] spell";

rule succeeds.

Effect of casting mend at something:

record outcome "which almost imperceptibly straightens and tidies itself, but with no real effect";

rule succeeds.

Effect of casting mend at a person:

record outcome "which pats [the second noun] on the head, to no practical benefit";

rule succeeds.

Definition: A person is undead if exorcise undead is its defensive charm.

This is the exorcise undead removal rule:

repeat with turned one running through the undead people in the location:

remove the turned one from play;

award the permanent strength of the turned one points.

Effect of casting exorcise undead at:

if an undead person is in the location:

record outcome "which, as if a kind of lassoo, loops around [the list of undead people in the location] and drags the unclean down beneath the earth";

record event the exorcise undead removal rule;

rule succeeds;

record outcome "which throws a kind of lassoo around nothing in particular, then pulls tight until it disappears";

rule succeeds.

Effect of casting silence at:

record outcome "and a silence settles mufflingly around your feet";

now the player is affected by silence;

rule succeeds.

Effect of casting summon elemental at:

record outcome "and there is a horrendous tearing sound from the very earth";

move Zoorl to the location;

now Zoorl is indifferent;

rule succeeds.

Effect of casting web at a hostile monster:

record outcome "and the silken strands drape themselves over [the second noun], impeding all movement";

now the second noun is affected by web;

rule succeeds.

After printing the name of a person who is affected by web when we are looking, say " (webbed)".

For calculating combat modifiers of a person who is affected by web:

modify to-hit roll by -8 for "trying to fight through web";

continue the activity.

Effect of casting web at:

record outcome "but the silken strands fall away, half-hearted and half-meant";

rule succeeds.

Notes

[1]. This didn't occur to the author at all - one of the playtesters tried it, and then the idea seemed irresistable. Poisoning a weapon adds a whole extra die and +2 in adds, so there's quite a reward for anyone resourceful enough to think of this.

[2]. An exceptionally unpopular rule with players, this. But it does make the reward for those who discover "make sanctuary" all the sweeter.