Glass — 9 of 25

Emily Short

Release 1

Section 3 - Handling Legitimate Remarks

[And now at last we define the "mentioning" action.]

Mentioning is an action applying to one visible thing.

Carry out mentioning:

say "'[awwk]!' you [exact verb]. '[The noun][if a random chance of 1 in 3 succeeds]! [The noun][end if]!'";

[The default behavior is to print the parrot's speech (in carry out, because this is one of those rare circumstances where the action involves generating some text -- just as examining prints the description in carry out). Then the non-player characters respond by trying to fit this outcry into the flow of their conversation. We make them silent at that point ("now the old lady is passive") so that their regular flow of every-turn conversation will be interrupted to deal with your intrusion.]

Report mentioning:

now the old lady is passive;

relate the current subject with the noun, directly;

change last subject to current subject;

change the current subject to the noun.

[We can also override this behavior by giving constant responses to specific remarks:]

Instead of mentioning blank: try squawking.

Instead of mentioning God for the first time:

say "'God!' you exclaim. All eyes turn slowly towards you.

'Heavens,' says the Prince mildly. 'A pet with theological leanings. How unusual. You're most fortunate in your domesticated animals, madam.'

The old lady gives you a long, narrow-eyed look. Apparently she does not share the Prince's feelings on that topic."

Instead of mentioning God for the third time:

say "'God!' you [exact verb] again. 'Christ? Buddha? Zeus?'

'Show-off,' Theodora mutters under her breath.

'That will be enough from you,' says the old lady, looking at you with eyes almost as beady as your own."

Carry out mentioning heirs when the current subject is king's health:

say "'NEED BABIES,' you [exact verb]. 'Heirs to the kingdom, heirs to the kingdom!'" instead.

After mentioning the King's Health for the first time:

say "The Prince glances your way and offers you a small, smiling salute."

After mentioning heirs for the first time:

say "Blood rushes up into the Prince's cheeks. He doesn't look your way."

[And what happens if the player squawks something that the characters are already discussing?]

Report mentioning the current subject:

repeat through Table of Bad Bird Excuses


say "[response entry][paragraph break]";

blank out the whole row;

now the player is disgraced;

rule succeeds;

end repeat.

Table of Bad Bird Excuses

"'Don't mind our parrot,' says the lady, smiling at the Prince. 'It has very bad manners.'

The Prince glances at you. 'I imagine any manners at all would be above average for a bird.'

Lucinda smirks."
"'It just repeats things it hears,' says Lucinda."
"'Ssh,' says Lucinda to you."
"'Honestly,' says Lucy.

'It was raised by sailors,' the old lady says.

'Pirates,' Theodora embellishes. She likes pirates.

The old lady kicks her ankle."