Glass — 23 of 25

Emily Short

Release 1

Section 6 - Theodora Being Tried

Checking Theodora is a scene.

Checking Theodora begins when Prince unties Theo boots. Fitting ends when Checking Theodora begins. When Checking Theodora begins:

change left hand status line to "Trying the slipper on Theodora";

change last subject to current subject; change the current subject to Theo; change the target subject to Theo; change the conversation set to Table of Theodora Checking Remarks.

Every turn during Checking Theodora:

repeat through Table of Theodora Checks


say "[response entry][paragraph break]";

blank out the whole row;

rule succeeds;

end repeat.

Checking Theodora ends when the number of filled rows in the Table of Theodora Checks is 0.

When Checking Theodora ends:

say "The Prince is silent for a moment, looking at the shoe. 'It's you,' he says. 'It's you, Theodora! Why didn't you tell me?'

The old lady turns away, tucking something into her pocket: something glassy and glinting.";

move the pocket to the old lady.

The pocket is a thing. The description of the pocket is "It bulges with something shaped like a shoe."

Table of Theodora Checking Remarks

blankLucinda"'One at a time, bird,' mutters the Prince. Theodora giggles."
blankshoe"'Yes,' says Lucinda to you. 'You're very smart.'"

Table of Theodora Checks

"The old lady slips her hands into the pockets of her skirt and leans back."
"The Prince drops to kneel at Theo's feet. He looks dubiously at the shoe. 'Do you happen to know whether this goes on the left foot, or the right one?' he asks. 'It's very--'

'You can try it on both,' says Theodora. 'If you want.'

He begins to slip it onto her left foot. It won't go, not at all. 'That's certainly not it,' he says, smiling at her quickly.

She twitches her skirt, giving him -- you imagine, since you are at the wrong angle -- a passing view of quite a lot more than her ankles. He blinks once but does not allow himself comment."
"'Right,' he says. 'Other foot now.' He slides the shoe on, and it does go considerably further. 'Tell me if I'm hurting you,' he says.

'You're not, not at all,' Theo assures him on a wince.

'Shoes are worn tight this year,' puts in the old lady."
"The Prince stops his work with the shoe. 'I can't -- this must not be --'

'Oh, for pity's sake,' says the old lady. 'You haven't the least idea how women dress. Let me.' And she kneels at Theodora's feet, shooing the Prince aside, and gives a firm tap to the heel of the shoe; at which point it slides on.

'Bless me,' she says."

To decide whether Prince unties Theo boots:

if Fitting is happening and Theo is the current subject, yes;

if Fitting is happening and time since Fitting began is 4 minutes


say "'I can start if you like,' says Theo at last. 'You can try it on me.'";


end if;


Theodora Endgame is a scene. Theodora Endgame begins when Checking Theodora ends.

Theodora Endgame ends in Theodora Marriage when the time since Theodora Endgame began is two minutes.

Instead of mentioning during Theodora Endgame:

say "'[noun]!' you [exact verb].

Theodora blows you a little kiss."

Instead of mentioning Theo during Theodora Endgame:

say "'Theodora! Congrat-- awwk!'

Theodora nods prettily in your direction. Oh yes, it will be a golden cage for you, soon enough..."

Instead of mentioning shoe during Theodora Endgame:

say "'Slipper!' you screech. 'Wrong slipper! Wrong slipperslipper! In the pocket! Old lady!' It's the most complicated thing you've had to say in years, and your head aches by the time you're done.

The Prince looks at you for a long moment, then turns to the old lady; who shrugs, as though to say that she knows the game is up. Fishing in her pocket she draws out the true slipper. 'The other one is only a little larger,' she says, handing the real one over. 'Theodora's feet are quite dainty, on the whole.'

'You are a harridan,' says the Prince. 'A conniving, treacherous, beastly woman with no knowledge of love...'

'You could still try the shoe on Lucinda,' she suggests mildly.

He snorts. 'I thank you, I do not want to find my bride here. I imagine everyone under this roof is tainted with a little of the same venom.'

'That is the truth,' Lucinda murmurs; but he is already going, going, gone.";

end the game saying "The Prince departs in anger"

When Theodora Endgame ends in Theodora Marriage:

say "The Prince pulls Theodora toward him. 'You are a woman of unexpected depths,' he says softly. 'All these years I have known you, seen you here and there, and thought that you were such a simple straightforward creature...'

She blinks at him, then says, 'I hope you are not angry.'

He laughs, and touches her cheek; and she kisses him.

Lucinda bites her lip. 'Well,' says the old lady briskly, standing. 'How many unexpected turns life brings to us.' And she pulls the bellpull with unnecessary force.";

end the game saying "Theodora and the Prince are married".

Every turn when Theodora Endgame is happening and the time since Theodora Endgame began is 1 minute:

say "There is an odd silence, as though no one is sure what to do or say now. But it will break momentarily."

Instead of waiting when Theodora endgame is happening for the first time:

say "You do nothing. The old lady stares at you, and you stare back."

Instead of waiting when Theodora endgame is happening for the second time:

say "A slow smile crosses the old lady's face."