Glass — 15 of 25

Emily Short

Release 1

Section 3 - Insults and Compliments

[The ability to insult or compliment characters arose from changes to the ATTACK command, where we decided to make ATTACK into a verbal assault rather than a physical one. It then seemed only reasonable to provide a way to make up to a person, as well.]

Instead of attacking someone: now the player is disgraced;

say "'[rude word] [noun]!' you shriek. '[if a random chance of 1 in 2 succeeds][Awwk]! [end if][if a random chance of 1 in 3 succeeds][rude word]! [end if][rude word]!'

[The noun] glares at you."

Instead of attacking the prince for the first time:

now the player is disgraced;

say "'[rude word] [noun]!' you shriek. '[if a random chance of 1 in 2 succeeds][Awwk]! [end if][if a random chance of 1 in 3 succeeds][rude word]! [end if][rude word]!'

'What a quaint conversation piece your pet is,' remarks the Prince, unruffled.

'Oh, that's not the only curious thing we keep around the house,' says Lucinda."

To say rude word:

choose a random row in the Table of Insults; say "[response entry]".

Table of Insults

response
"Fool"
"Nitwit"
"Lamebrain"
"Coward"
"Twit"
"Baggage"
"Cutpurse"
"Pinchpenny"
"Lickspittle"
"Moldy rogue"
"Scurvy companion"
"Canker-blossom"
"Stinky"
"Lack-linen"
"Frog-face"

Understand the commands "insult" or "offend" or "reprimand" or "upbraid" as "attack".

Instead of attacking something: say "Not even the ferocious grip of your claws would make much difference."

[But, having provided this other meaning for "attack", we don't want to misunderstand the commands that suggest a strictly physical approach:]

Understand the command "kill" as something new. Understand the command "hit" as something new. Understand the command "murder" as something new.

Understand "kill [text]" as a mistake ("Invective is your only weapon."). Understand "murder [text]" as a mistake ("Invective is your only weapon."). Understand "hit [text]" as a mistake ("Invective is your only weapon.").

Understand "compliment [someone]" or "flatter [someone]" or "seduce [someone]" as complimenting. Complimenting is an action applying to one visible thing. Carry out complimenting: do nothing.

Report complimenting:

say "'[nice word] [noun]!' you squawk coaxingly. '[if a random chance of 1 in 2 succeeds][Awwk]! [end if][if a random chance of 1 in 3 succeeds][nice word]! [end if][nice word]!'

[The noun] ignores you."

Instead of complimenting the player: try mentioning birds.

Instead of complimenting someone when the player is disgraced:

say "'[nice word] [noun]!' you squawk coaxingly. '[if a random chance of 1 in 2 succeeds][Awwk]! [end if][if a random chance of 1 in 3 succeeds][nice word]! [end if][nice word]!'

'Pretty,' remarks [the noun], 'but you will not earn your way back into our good graces that easily.'

You hide your head under your wing sulkily.".

To say nice word:

choose a random row in the Table of Flattery;

say "[response entry]".

Table of Flattery

response
"Darling"
"Sweeting"
"Pretty"
"Nice"
"Sugarplum"
"Splendid"
"Adorable"