Glass — 13 of 25

Emily Short

Release 1

Chapter 4 - Your Behavior

Section 1 - Looking and Waiting

[Because this game relies minimally on interaction with physical objects, the usual looking rules, and rules for movement, are modified to focus the player's attention on the flow of conversation.

In particular, we begin by overriding the default behavior that prints room descriptions at the outset of the game, and re-writing LOOK so that it doesn't actually give any information.

Since we're also changing the status bar, the player will never see the fact that we've labeled our location "Stage".]

Procedural rule: ignore the room description heading rule. Rule for printing the name of the Stage: do nothing.

Instead of looking for the first time:

if turn count is 1

begin;

say paragraph break;

say "The Prince sits awkwardly on the couch, holding his glass slipper and trying to keep it from crushing. Lucinda and Theodora have the ends of the same couch, and they are taking turns seeing who can bend lowest and show off the most cleavage; while the old lady, in her wing chair, carries on about nonsense. For instance:

'Do tell me about your father's health,' she says, leaning toward the Prince. 'Is he still ailing? Has the Spanish doctor been able to do anything for him?'

The Prince looks uncomfortable: this line of reason leads directly to the problem of heirs. 'I believe so, madam,' he replies, with a bit of constraint.[line break]"; [1]

end if.

Instead of looking:

say "You give the place a once-over with your right eye. Then you turn your head and look at everything through your left eye. It doesn't make any difference. The farther parts of the room remain out of focus."

Instead of examining the player:

say "It's hard to have a good look at the moment, but everything feels in order, properly preened, feathers lying as they ought."

Instead of waiting:

choose a random row in the Table of Waiting;

say "[response entry][paragraph break]".

Table of Waiting

response
"You hold your peace."
"You shift your weight from claw to claw."
"You walk down to the other end of the perch."
"You turn your head and look at everyone out of the other eye, for a change."
"You stretch your useless wings and fold them again."
"You yawn."
"Outside on the street something rattles by."
"The floorboards creak overhead. No one looks up."

Note

[1]. This bit of conversation might conventionally have gone before the banner in a When play begins... passage; but since we have no room descriptions in this game, this would mean having a banner immediately followed by a command prompt. So I decided instead to go with a null prologue and put this bit of chat after the banner but before the command prompt.