Bronze — 44 of 46

Emily Short

Release 12

Section 3 - Miscellaneous Other Assistance for Novices

Taking inventory is acting confused. Looking is acting confused. Examining an examined thing is acting confused.

After acting confused for the sixth turn:

if in the Great Dining Hall, do nothing;

otherwise remind about assistance.

To remind about assistance:

say "(If you are feeling lost, try typing HELP for complete instructions, HINT for general guidance on what to do next, or THINK ABOUT a specific item that is giving you trouble.)"

After waiting for more than three turns:

say "Matters will not mend themselves on their own."

After waiting for more than six turns:

remind about assistance.

Understand "who" or "what" or "when" or "where" or "why" or "how" or "who's" or "what's" or "when's" or "where's" or "why's" or "how's" as "[query]".

After reading a command:

if the player's command includes "[query]" begin;

say "[story title] understands commands, such as '[command prompt]examine [a random thing that can be seen by the player]', but not questions. You can get some information about the current game state with commands such as LOOK, EXAMINE, INVENTORY, PLACES, and OBJECTS; or, for more instructions, type HELP.";

reject the player's command;

end if;

if the player's command includes "please" begin;

say "(There is no need to say please.)";

cut the matched text;

end if.

Understand the command "breathe" as "smell".

Understand "look [something]" as examining. [1]

Understand the commands "see" and "view" as "look". Understand the commands "observe" and "inspect" as examine.

Understand the commands "wander" and "proceed" and "stroll" and "stride" and "strut" and "sneak" and "creep" and "rush" as "walk".

Understand the commands "hand" and "deliver" as "give".

Understand the command "depart" as "leave".

Understand the command "carve" as "cut".

Understand the commands "grab" and "bring" and "fetch" and "steal" and "acquire" and "snatch" as "take".

Understand the commands "place" and "stick" and "shove" and "stuff" as "put".

Understand the commands "strike" and "smack" and "injure" as "hit".

Understand the commands "scream" and "yodel" and "yell" and "holler" and "roar" as "shout".

Understand the command "board" as enter.

Understand the commands "toss" and "fling" and "hurl" as "throw".

Understand the commands "melt" and "ignite" and "incinerate" and "kindle" as "burn".

Understand "bite [something edible]" as eating. Understand "bite [something]" as attacking.

Understand "kick [something]" or "kick in/down/through [something]" as attacking.

Understand "start [something]" as switching on. Understand the command "activate" as "start". Understand "start over/again" as restarting the game.

Understand "stop [something]" as switching off. Understand the command "deactivate" as "stop".

Understand "reach for/towards/to [something]" as taking.

Understand "throw away [something]" as dropping.

Understand "jump on/onto [something]" as entering.

Understand "get down" as exiting.

Understand "around/about/away" as "[around]". Understand "castle/palace" as "[location name]". Understand "the [location name]" or "[location name]" as "[castle]". Understand "here/room/space/location" as "[locale]". Understand "in/at [locale]" or "in/at this [locale]" or "this [locale]" or "[locale]" as "[locally]".

Understand "wait [around]" or "wait [locally]" as waiting. Understand "wait in [any room]" as waiting within.

Waiting within is an action applying to one thing.

Carry out waiting within:

if the noun is the location, try waiting instead;

try approaching the noun;

if the noun is the location, try waiting instead;

otherwise stop the action.

Understand "look [around]" as looking.

Understand "go [around]" as going. Understand "go [around] [castle]" as going. Understand "search [castle]" or "look [around] [castle]" as going.

Understand "put out [something]" as extinguishing. Understand "blow out [something]" as extinguishing. Understand "blow on/in/through [something]" as blowing. Understand "extinguish [something]" as extinguishing. Understand the command "snuff" as "extinguish". Blowing is an action applying to one thing.

Understand "show inventory/invent/i/inv" as taking inventory.

Understand "pray for/to [text]" as praying to. Praying to is an action applying to one topic. Carry out praying to: say "You can see no immediate result."

Extinguishing is an action applying to one thing. Carry out extinguishing: say "[The noun] would have to be on fire, first." Instead of extinguishing the candle: try blowing the candle.

Understand "out of/from" or "from" as "[out of]". Understand "down on" or "on" as "[on]".

Understand "get [things inside] [out of] [something]" as removing it from.

Understand "set [things preferably held] down" as dropping. Understand "set [things preferably held] [on] [something]" as putting it on. Understand "set down [things preferably held]" as dropping.

Understand "end" as quitting the game.

[Understand "i [text]" as a mistake ("(Only imperative commands, such as LOOK, EXAMINE, GO WEST, and TAKE THE KEY, are understood. For more instructions, type HELP.)").]

Understand "finger/fingers/hand/hands/fist/fists/feet/foot/arm/arms/legs/leg/head/face/mouth/eyes/nose/ears/ear/eye" as "[body part]". Understand "my [body part]" or "[body part]" as "[specific anatomy]".

Understand "by/with/using" as "[means]".

After reading a command:

if the player's command includes "head [a direction]"

begin;

if the player's command includes "head", replace the matched text with "go";

end if;

if the player's command includes "[means] [specific anatomy]"

begin;

say "(It is usually not necessary to refer to specific body parts.)";

cut the matched text;

while the player's command includes "[means] [specific anatomy]", cut the matched text;

end if;

if the player's command includes "[specific anatomy]"

begin;

say "(It is usually not necessary to refer to specific body parts.)";

replace the matched text with "me";

while the player's command includes "[specific anatomy]", replace the matched text with "me";

end if.

Before putting something wearable on the player:

if the player does not have the noun, try taking the noun;

if the player has the noun, try wearing the noun instead. [2]

Before removing something worn by the player from the player:

try taking off the noun instead. [3]

Understand the command "ransack" as "search". Understand "search [any visited room]" as ransacking. Ransacking is an action applying to one thing.

Carry out ransacking:

if the location is not the noun, try approaching the noun;

otherwise try looking.

Understand the commands "wash" and "cleanse" as "clean".

Notes

[1]. This is not good syntax but has been shown to be used frequently by both novice players and players whose only IF contact is very old IF.

[2]. handles PUT THE HELMET ON MY HEAD

[3]. handles REMOVE THE HELMET FROM MY HEAD, TAKE THE HELMET OFF MY HEAD, etc.