Bronze — 38 of 46

Emily Short

Release 12

Section 6 - Going Nowhere

[Part of the minimalist flavor of this game is a reserve -- one might even say negligence -- about listing exits in the room descriptions. The regular room descriptions are often quite short, and we don't want them overwhelmed by text about the doorways out. And besides, exits are always shown in full in the status line.

All the same, as a politeness to the player, we will always remind him about exits in the event that he strikes off in the wrong direction. Our exit-listing will follow the same rules as the status line, when it comes to identifying dark and lighted exits.]

Instead of going nowhere:

say "[exit description]"

Instead of exiting when the player is in a room:

try departing the location.

Instead of departing a room when in darkness:

say "By dead reckoning, you head back towards where you think the surface ought to be...";

try approaching the Servant Quarters.

To say exit description:

let count of exits be 0;

repeat with way running through directions

begin;

let place be the room way from location;

if place is a discernible room

begin;

increase count of exits by 1;

end if;

end repeat;

if count of exits is 0

begin;

say "You appear to be lost in here, except that you recall you came in from [the opposite of the former direction]. If necessary you can always try going to a room you've already visited, or heading roughly out.";

rule succeeds;

end if;

say "From here, you can head ";

let index be count of exits;

repeat with way running through directions

begin;

let place be the room way from location;

if place is a discernible room

begin;

decrease index by 1;

say "[way]";

if index is greater than 1, say ", ";

if index is 1

begin;

if the count of exits is greater than 2, say ",";

say " and ";

end if;

if index is 0, say ".";

end if;

end repeat.