Bronze — 30 of 46

Emily Short

Release 12

Part 3 - The Plot

Chapter 1 - Encouragement

[Here we have a few light elements to nudge the player along. These are fairly trivial and fade out as the game proceeds, but during the first portion, when he has nothing to do but explore, we want to keep him focused on moving from room to room, so that he knows this is the right thing to be doing.]

When play begins:

change the player to seen;

say "When the seventh day comes and it is time for you to return to the castle in the forest, your sisters cling to your sleeves.

'Don't go back,' they say, and 'When will we ever see you again?' But you imagine they will find consolation somewhere.

Your father hangs back, silent and moody. He has spent the week as far from you as possible, working until late at night. Now he speaks only to ask whether the Beast treated you 'properly.' Since he obviously has his own ideas about what must have taken place over the past few years, you do not reply beyond a shrug.

You breathe more easily once you're back in the forest, alone.

[paragraph break]"

The Search is a scene. Search begins when play begins. Search ends when the player can see the Beast.

Scouring Main Castle is a scene. Scouring Main Castle begins when play begins. Scouring Main Castle ends in completion when every room in the Main Castle is visited. Scouring Main Castle ends in irrelevance when Search ends.

When Scouring Main Castle ends in completion:

if the location is the Ground Floor

begin;

say "Upstairs. That must be the solution. You'll find him up there, and everything will go back to normal; as it always does after a fight or disagreement or odd patch. Sooner or later things just right themselves and resume as they have always gone.";

rule succeeds;

end if;

say "So he's not among the kitchen things.";

if a room in Apartments is unvisited

begin;

suggest upstairs;

otherwise;

if every room in Old Castle is visited,

suggest downstairs;

otherwise suggest old castle;

end if.

Scouring Old Castle is a scene. Scouring Old Castle begins when the location is in Old Castle and Scouring Old Castle has not happened. Scouring Old Castle ends in completion when every room in Old Castle is visited. Scouring Old Castle ends in irrelevance when Search ends.

When Scouring Old Castle ends in completion:

say "He's not down here, then, in the east wing.[paragraph break]";

if a room in Main Castle is unvisited

begin;

suggest Main Castle;

otherwise;

if every room in Apartments is visited,

suggest downstairs;

otherwise suggest upstairs;

end if.

Scouring Upstairs is a scene. Scouring upstairs begins when the location is in Apartments and Scouring upstairs has not happened. Scouring upstairs ends in completion when every room in Apartments is visited. Scouring upstairs ends in irrelevance when Search ends.

When Scouring Upstairs ends in completion:

say "He's not upstairs, then: there's nowhere in these rooms he could have been hiding, no space large enough to conceal him.[paragraph break]";

if a room in the Old Castle is unvisited

begin;

suggest old castle;

otherwise;

if every room in Main Castle is visited,

suggest downstairs;

otherwise suggest Main Castle;

end if.

To suggest Main Castle:

if the Dining Hall is visited and the Kitchen is visited and the Quarters is visited

begin;

say "Perhaps he's in one of the side rooms you've not visited yet...?";

otherwise;

say "There is still the chance that he's somewhere in the kitchen wing, west of the entrance hall. Maybe he got hungry.

(He never liked to eat in the dining hall alone, and took it up only when you were around. But maybe he's gone there for some reason anyway?)";

end if.

To suggest downstairs:

say "He must have gone into one of the more... difficult portions of the castle. The state rooms, or the crypt. One of the places he knows you hate to visit alone.

This does not bode well for his state of mind. (Will he be angry? It has been a long time since he was truly angry at you... But you cannot deal with that until you find him.)";

To suggest upstairs:

say "A new thought occurs to you: perhaps he's waiting for you upstairs, diverting himself with one of the toys or game he brought you. No point in worrying until you have checked the apartments, surely."

To suggest Old Castle:

say "Perhaps he's [if location is in the Apartments]downstairs somewhere,[otherwise]over[end if] in the east wing. That would make sense. You find those rooms dreary and cold, but he spends time there when he wishes to be alone; perhaps..."

Foodgetting is a scene. Foodgetting begins when Search ends. When foodgetting begins:

say "'Nothing bad will happen for the first seven days,' he said, when you left.

And yet here he is, looking very nearly dead."

Understand "greet [text]" as a mistake ("Unlikely to help much.").

Foodgetting ends when the player carries the feast. When foodgetting ends:

say "Perhaps he will feel better when he has eaten, you reflect. He has always had a large appetite -- the result of his change in form, he tells you.

He used to mock your dainty eating, and sit at table long after your plate was empty; and make a game of guessing foods that might tempt you to eat even a little more; vanishing into the kitchen to instruct the staff, and returning a little later; saying roguishly, 'This, I think you will like...'

In your defense, you never had sugared violets at home."

Before going to an unvisited room (called destination) during Search:

if destination is the Crystal Bedroom or the destination is the Gilded Balcony, continue the action;

if destination is in the State Rooms and the windchimes are in the Rose Garden, continue the action;

if destination is dark and the player is not carrying the candle, continue the action;

if most of the rooms are visited

begin;

move the Beast to destination;

end if.

Considering Beast is a scene. Considering beast begins when the player can see the beast and Considering Beast has not happened and the player is wearing the girdle. When Considering Beast begins, say "When you look at the Beast this time -- it must be the influence of the girdle -- you see him as more animal than human, though you long ago learned to discern a man's expressions on his face.

[italic type]I was afraid of him[roman type], says the memory of Yvette in your head, as though she's trying to justify herself to you. There are other thoughts as well, murkier; but you are left with the impression that she killed herself, in the end, not because of her family's misfortunes or the lord she was separated from; but because she was carrying a child, and feared that it would be born some kind of monster." Considering Beast ends when the time since considering beast began is 1 minute.