StartEnd MenuPages

version 1 by ShadowChaser

  • Home page
  • Beginning
  • Previous
  • Next



  • Section 4 - the title screen rule

    The first when play begins rule (this is the title screen rule):
        if using the mature content warning option and the game_started is 0 begin;
            let continue_val be 0;
            while continue_val is 0 begin;
                clear the screen;
                redraw status line;
                say paragraph break;
                say "[the_disclaimer]";
                say paragraph break;
                let answer be yesno_answer_with_question "Do you wish to continue (Y / N)?";
                if answer is "NO" begin;
                    stop game abruptly;
                otherwise;
                    if answer is "YES" begin;
                        let continue_val be 1;
                        now the game_started is 1;
                    end if;
                end if;
            end while;
        end if;
        while not using the no title page option begin;
            clear the screen;
            redraw status line;
            play_start_music;
            say paragraph break;
            display_start_art;
            say line break;
            say "[the_game_title]";
            say paragraph break;
            say "[the_start_quotation]";
            say paragraph break;
            say "Please choose one of the following options:";
            say paragraph break;
            say fixed letter spacing;
            if using the menus option begin;
                say "Help menu : M[line break]";
            end if;
            say "Start the game : (SPACE)[line break]";
            say "Restore a saved game : R[line break]";
            say "Quit : Q";
            say variable letter spacing;
            say paragraph break;
            say "[the_start_footer_text]";
            say paragraph break;
            let k be 0;
            while k is 0 begin;
                let k be the chosen letter;
            end while;
            if k is 13 or k is 31 or k is 32 begin;
                clear the screen;
                make no decision;
            otherwise if k is 113 or k is 81;
                stop game abruptly;
            otherwise if k is 82 or k is 114;
                follow the restore the game rule;
            otherwise if k is 109 or k is 77;
                if using the menus option begin;
                    change the current menu to the intro_menu;
                    carry out the displaying activity;
                end if;
                pause the game;
            end if;
        end while.