Grouped Messages As Dialogue

version 1 by Ron Newcomb

  • Home page
  • Beginning
  • Previous
  • Next



  • Example: ** "Pet Shop People" - Tests basic operation of the extension by running the same test with two different observers.

        "Pet Shop People"

        Include Grouped Messages as Dialogue by Ron Newcomb.

        The observer is usually Bob.

        The pet store is room. Bob is a man in the pet store. Alice is a woman in the pet store. A collar and a brush are things in the pet store. Persuasion rule: rule succeeds. A pet carrier is a closed, openable container in the pet store. The pet store contains a white puppy and a black puppy.

        Test me with " test a-run / swap / drop all / test a-run / swap / / /".
        Test a-run with "take puppy / black / i/ take / puppy / x me closely / take collar / take collar".

        Section 1 - Bob's errorbook

        Bob's error are an rulebook. Bob's error rulebook have default success. The observations of Bob is Bob's error rules. [ ACTIVITIES MUST COME FIRST ]
        
        Rule for Bob's error when printing a parser error:
            if the parser error is only understood as far as, say "'[']ey man, I only know [']ow to [parser-understood words]. Don't know much about ['][parser-confusing words]['] and all,' he says.";
            otherwise continue the action.

        Rule for Bob's error when asking which do you mean:
            say "'Which one, man? I got [a prepared list delimited in sequential style].'".

        Rule for Bob's error when message of game error is LibMsg <what disambiguation>:
            say "'[The player's command] what?' says Bob.".

        Rule for Bob's error when message of game error is LibMsg <report player taking> and when the noun is the black puppy:
            say "'[']ere ya go.' Bob hands you [the noun]. '[']is name's Smokey.' He turns to the back of the shop. 'Ey Alice! What'dya say [']bout Smokey?'[line break]";
            if cannot defer to Alice, say "'Ah she can't hear me.'".

        Rule for Bob's error when message of game error is LibMsg <report player taking>:
            say "'[']ere ya go.' Bob hands you [a noun].[line break]".

        Section 2 - Alice's errorbook

        Alice's error are an rulebook. Alice's error rulebook have default success. The observations of Alice is Alice's error rules. [ ACTIVITIES MUST COME FIRST ]
        
        Rule for Alice's error when printing a parser error:
            if the parser error is only understood as far as begin;
                say "Alice looks confused for a moment. 'Just a minute. Hey Bob?' She repeats that to Bob, in the back.";
                if cannot defer to bob, say "'He doesn't hear me. I'll ask him when he gets back.'";
            otherwise;
                continue the action;
            end if.

        Rule for Alice's error when asking which do you mean:
            say "'Sure! Would you like [a prepared list delimited in disjunctive style]? Their names are Cottonball and Smokey.'".

        Rule for Alice's error when message of game error is LibMsg <what disambiguation>:
            say "'Sorry? What would you like to [player's command]?' says Alice.".

        Rule for Alice's error when message of game error is LibMsg <report player taking> and when the noun is the white puppy:
            say "'Cottonball is really sweet,' she says. Now in your arms, Cottonball pokes her nose into your shirt, as if she's looking for something.";

        Rule for Alice's error when message of game error is LibMsg <report player taking> and when the noun is the black puppy:
            say "'Smokey bites,' she says.";

        Rule for Alice's error when message of game error is LibMsg <report player taking>:
            say "Alice hands you [the noun]. 'Need anything else?'[line break]".

        Rule for Alice's error when game error is failing not out of world :
            say "'Let me know if I can help you with anything,' says Alice.".

        Section 3 - An pseudoaction specifically to change the observer

        Understand "swap" as a mistake ("[observer] goes into the back for something. [swap em][observer] is now waiting on you.").
        To say swap em: if observer is bob, now observer is alice; otherwise now observer is bob.

        Section 4 - The default errors are a rulebook
        
        Rule for default errors when message of game error is LibMsg <empty line>:
            say "Say again?".