Custom Library Messages

version 4/120212 by Ron Newcomb

  • Home page
  • Beginning
  • Previous
  • Next



  • Book - Plurality Phrases

    Chapter - For CLM regardless Plurality

    The prior named noun is an object that varies. The prior named noun is usually yourself.
    After printing the name (this is the notice plurality of printed object rule), mark the parameter-object in output.

    [ These are not in Plurality, or if they are, only operate on Things. Here, we allow operating on "nothing" to mean "whatever the story viewpoint is." ]

    To mark (target - an object) in output:
        now the prior named noun is the target;
        now the built-in S-substitution's decision is whether or not (the target acts plural).

    [generally, "those're" is awkward, and in colloquial speech, "they're" is frequently used.]
    To say That's-They're of (item - an object):
        mark item in output;
        if the item acts plural, say "They['s-'re]";
        otherwise say "That['s-'re]".

    To say 's-'re:
        let the form be the appropriate auxiliary inflection;
        if the form is at least the -ed past form or the form is the infinitive form, say " [are* in its form]"; [ We won't contract was, were, being, been, or be. ]
        otherwise say "[contraction-for-is in its form]".

    To say is-are of (item - an object):
        mark item in output;
        say are*.

    To say n't:
        if the story viewpoint is first person and the prior named noun is nothing and the story tense is present tense, say " not";
        otherwise say "n't".

    To say that-those-us of (item - an object):
        mark item in output;
        if the item is nothing:
            say "[us]";
        otherwise if the item acts plural:
            say "those";
        otherwise if the item is a person:
            if the item is female:
                say "her";
            otherwise if the item is not neuter:
                say "him";
            otherwise:
                say "that";
        otherwise:
            say "that".