Automated Verb Phrases

version 1/110416 by Ron Newcomb

  • Home page
  • Beginning
  • Previous



  • Section - Auxiliary Words and Phrases (in place of Section - Verb Phrase Generation unindexed in Custom Library Messages by Ron Newcomb)

    To say (main verb - an irregular verb):
        if the main verb is aren't*: [untested]
            now negation pending is true; [untested]
            now the main verb is are*;
        if the main verb is greater than end aux, say "[if the main verb is at least are*][aux for the main verb][end if][the main verb in its appropriate inflection][n't?]";
        now negation pending is false;
        now suffix eaten by auxiliary is [reset to] false;
        now passive voice is [reset to] false;
        now could-would-should is "";
        if restore-library-conjugation is not the zero conjugation:
            now the story tense is the story tense - restore-library-conjugation;
            now restore-library-conjugation is the zero conjugation.

    To say =>perfect:
        if the story tense is not in any perfect tense:
            now the story tense is the story tense + the perfect tense bitval;
            now restore-library-conjugation is restore-library-conjugation + the perfect tense bitval.

    To say =>continuous:
        if the story tense is not in any continuous tense:
            now the story tense is the story tense + the continuous tense bitval;
            now restore-library-conjugation is restore-library-conjugation + the continuous tense bitval.



    To say =>not: (- CLM_negation_pending = true; -).
    To say =>don't: (- CLM_negation_pending = true; -).
    To say =>doesn't: (- CLM_negation_pending = true; -).
    To say =>negation: (- CLM_negation_pending = true; -).
    To say =>would/=>will: (- (+ could-would-should +) = (+ "would" +); -).
    To say =>could/=>can: (- (+ could-would-should +) = (+ "could" +); -).
    To say =>passive: (- CLM_passive_voice = true; -).
    To say =>question: (- CLM_question_pending = true; -).


    [ possibly capitalised]
    [To decide what text is can/could: (- (+ the appropriate modal auxiliary form for "could" +) -).
    To decide what text is can't/couldn't: now negation pending is true; decide on the appropriate modal auxiliary form for "could".
    To decide what text is will/would: (- (+ the appropriate modal auxiliary form for "would" +) -).
    To decide what text is won't/wouldn't: now negation pending is true; decide on the appropriate modal auxiliary form for "would".]


    To say Qaux/Aux/¿¿ (x - an object): mark x in output; say "[uc][qaux for end aux]".
    To say Aux: say "[uc][qaux]".

    [ Passed in: question pending, negation pending, passive voice ]
    To say qaux: say qaux for end aux. [This one, capitalized, is used to begin a question, and is not much used otherwise]

    To say qaux for (main verb - an irregular verb): [This one, capitalized, is used to begin a question, and is not much used otherwise]
        now suffix eaten by auxiliary is [reset to] false;
        now first aux moved is question pending;
        if question pending is false, stop;
        if the main verb is aren't*: [untested]
            now negation pending is true; [untested]
            now the main verb is are*;
        if could-would-should is not "":
            say possibly capitalised appropriate modal auxiliary form for could-would-should;
            now suffix eaten by auxiliary is true;
            now negation pending is false;
        otherwise if the story tense is in any perfect tense:
            say possibly capitalised have+;
        otherwise if the story tense is in any continuous tense:
            say possibly capitalised are+;
        otherwise if passive voice is true:
            say possibly capitalised are+;
        otherwise if the main verb is are*:
            say possibly capitalised are+; [ are* isn't accepted here, but only simple present & past are left to deal with, so it still works. I think. ]
        otherwise: [ Never use "do" with "is". Produce "Is he it?" or "Is he not it?" instead.]
            say possibly capitalised do+;
            now suffix eaten by auxiliary is true;
            now first aux moved is false; [ A new aux word, do, was created, rather than moving a pre-existing aux word to the front of the question. ]
        say "[n't?] ".

    To say aux: say aux for end aux. [ For a regular verb, a suffix, or just an unknown kind of verb. ]

    To say aux for (main verb - an irregular verb): [unindexed; authors need only use [aux] ]
        if could-would-should is not "":
            if first aux moved is false, say "[the appropriate modal auxiliary form for could-would-should][n't?] ";
            now suffix eaten by auxiliary is true;
            now first aux moved is [definitely reset to] false; [in case the following branch is taken as well]
        if the story tense is in any perfect tense:
            if first aux moved is false, say "[have+][n't?] "; [ have+ haven't+ ]
            now first aux moved is [definitely reset to] false;
            if the story tense is in any continuous tense, say "been ";
        otherwise if the story tense is in any continuous tense:
            if first aux moved is false, say "[are+][n't?] ";
            if first aux moved is true and the story viewpoint is first person and the prior named noun is nothing and story tense is continuous present tense and negation pending is true:
                say "not "; [to avoid "Am I --- carrying..."]
                now negation pending is false;
            now first aux moved is [definitely reset to] false;
        otherwise if negation pending is true and passive voice is false and the main verb is not are*:
            say "[do+][n't] ";
            now suffix eaten by auxiliary is true;
        if passive voice is true and first aux moved is false:
            if the story tense is in any continuous tense:
                say "being ";
            otherwise if the story tense is in any perfect tense:
                say "been ";
            otherwise:
                say "[are+][n't?] ";
        if negation pending is [by some miracle still] true [and the main verb is are*] and question pending is true:
            say "not "; [ are* as simple question: "Am I not it?" ]
            now negation pending is false;
        now could-would-should is [reset to] "";
        now first aux moved is [reset to] false.


    [To decide which irregular verb is end aux: (- 0 -). [ This is for any case where a [-s], [e-s], [-es], or [-ies] isn't used. ]]
    To say ??: (- if ((+ question pending +)) print "?"; else print "."; (+ question pending +) = false; -). [line break problems?]


    Automated Verb Phrases ends here.