Hyperlink Combat System

version 1 by Philip Black

  • Home page
  • Beginning
  • Previous
  • Next



  • Section - Weapons
    To ready is a verb.
    Weapon is a kind of thing. Shield is a kind of thing. Armour is a kind of thing.
    Every person has a number called accuracy.
    Every thing has a number called accuracy bonus. [Bonus to hit]
    Every thing has a number called Max Range. [how far away it can hit] Max Range is usually 1.
    Every thing has a number called Min Range. [how far away it can hit] Min Range is usually 0.
    melee weapon is a kind of weapon. ranged weapon is a kind of weapon. thrown weapon is a kind of weapon.
    A weapon can be readied. A weapon is usually not readied.
    [A weapon can be Ammo Required. A weapon is usually not Ammo Required.]
    Readying is an action applying to one visible thing.
    Understand "ready [thing]" and "equip [thing]" as readying. Understand "wield [thing]" and "use [weapon]" as readying.
    Does the player mean readying a readied weapon: it is unlikely.
    Check readying (this is the cannot ready what is already readied rule):
        if the noun is readied and the noun is enclosed by the player:
            [take no time;]
            say "You are already wielding [the noun]." instead.
    Check readying (this is the cannot ready what is not a weapon rule):
        if the noun is not a weapon:
            [take no time;]
            say "You can only ready weapons." instead.
    First carry out an actor readying (this is the implicit taking when readying rule):
        if the actor does not enclose the noun:
            try the actor taking the noun.
    Carry out an actor readying (this is the carry out readying when enclosing rule):
        if the actor encloses the noun:
            now the noun is readied.
    Last carry out an actor readying (this is the unready all other weapons rule):
        if the noun is readied:
            repeat with item running through things enclosed by the actor:
                if the item is not the noun and the item is readied:
                    now the item is not readied.
    Last report an actor readying (this is the standard report readying rule):
        if the noun is readied:
            say "[The actor] [ready] [the noun].";
        otherwise:
            if the actor encloses the noun:
                say "[The actor] fool[s] around with [the noun], but fail[s] to ready it.";
            otherwise:
                say "[The actor] attempt[s] to ready [the noun], but cannot get a hold on it.".