Hyperlink Combat System

version 1 by Philip Black

  • Home page
  • Beginning
  • Previous
  • Next



  • SECTION - ATTACKING
    The block attacking rule is not listed in any rulebook.
    Understand "attack [thing]" as attacking.
    Does the player mean attacking a Subdued person: it is unlikely.
    Does the player mean attacking a Hostile person: it is very likely.
    Does the player mean attacking a passive person: it is likely.
    Does the player mean attacking the player: it is very unlikely.
    [Does the player mean attacking a readied weapon carried by the player: it is very unlikely.]
    Does the player mean attacking a thing carried by the player: it is very unlikely.
    Check attacking when the noun is not a person (this is the only attack persons rule):
        say "Things are not your enemies." instead.
    Check attacking a Subdued person (this is the only attack the living rule):
        say "[The noun] is already defeated." instead.
    Check attacking the player (this is the do not kill yourself rule):
        say "Quit hitting yourself!" instead.
    A check attacking rule (this is the do not attack Friendly people rule):
        if the faction of the player is the faction of the noun:
            say "[The noun] is your friend, not your enemy!" instead.
    A check attacking rule (this is the do not attack neutral people rule):
        If the noun is Non-Combat:
            Say "[line break][Noun] is not your enemy![line break]";
            reject the player's command;
        Otherwise if the noun is NOT Friendly:
            Let TaggedX be the faction of the noun;
            repeat with item running through people in the location:
                If the faction of item is TaggedX:
                    Now item is Hostile;
        Otherwise:
            say "[The noun] is not your enemy." instead;