Room Description Headings

version 1/090620 by Erwin Genstein

  • Home page
  • Beginning
  • Previous
  • Next



  • Section RDH/I/3 - Rules For New Activities

    Rule for room description headings (this is the embolden the apparent location rule):
        say bold type;
        continue the activity.

    Rule for room description headings (this is the name the apparent location rule):
        carry out the naming the apparent location activity;
        continue the activity.
        
    Rule for room description headings (this is the stop emboldening the apparent location rule):
        say roman type;
        continue the activity.
        
    Rule for room description headings (this is the list enclosures after the apparent location rule):
        carry out the listing enclosures activity;
        continue the activity.
        
    Rule for room description headings (this is the line break after the room description heading rule):
        say line break;
        continue the activity;
        
    Rule for room description headings (this is the run paragraph on after the room description heading rule):
        say run paragraph on with special look spacing;
        continue the activity.
        
    Rule for naming the apparent location (this is the we might appear to be in darkness rule):
        if the apparent location is nothing:
            begin the printing the name of a dark room activity;
            if handling the printing the name of a dark room activity,
                issue miscellaneous library message number 71;
            end the printing the name of a dark room activity;
        continue the activity.

    Rule for naming the apparent location (this is the we might appear to be in the location rule):
        if the apparent location is the location:
            say "[apparent location]";
        continue the activity.
            
    Rule for naming the apparent location (this is the we might appear to be in something rule):
        if the apparent location is not nothing and the apparent location is not the location:
            say "[Rdh the apparent location]";
        continue the activity.

    To deduce the enclosure ancestry count:
        let the current enclosure be the player's enclosure;
        now the enclosure ancestry count is zero;
        while the current enclosure is not the apparent location and the current enclosure is not nothing:
            now the current enclosure is the visibility-holder of the current enclosure;
            if the current enclosure is not the apparent location and the current enclosure is not nothing:
                increase the enclosure ancestry count by one.

    The last for listing enclosures rule (this is the default listing enclosures rule):
        deduce the enclosure ancestry count;
        carry out the describing the player's enclosure activity;
        carry out the describing the player's enclosure ancestry activity.

    The last for describing the player's enclosure rule (this is the default describing the player's enclosure rule):
        if the player's enclosure is not the apparent location:
            now the described enclosure is the player's enclosure;
            now the enclosure ancestry index is zero;
            carry out the printing an enclosure description activity.

    The last for describing the player's enclosure ancestry rule (this is the default describing the player's enclosure ancestry rule):
        now the enclosure ancestry index is zero;
        now the described enclosure is the player's enclosure;
        while the described enclosure is not the apparent location and the described enclosure is not nothing:
            now the described enclosure is the visibility-holder of the described enclosure;
            increase the enclosure ancestry index by one;
            if the described enclosure is not the apparent location and the described enclosure is not nothing:
                carry out the printing an enclosure description activity.

    The last for printing an enclosure description rule (this is the default printing an enclosure description rule):
        carry out the opening an enclosure description activity;
        carry out the printing an enclosure preposition activity;
        carry out the describing an enclosure activity;
        carry out the closing an enclosure description activity.

    The last for opening an enclosure description rule (this is the open enclosure descriptions with a parenthesis rule):
        say " (";

    The last for closing an enclosure description rule (this is the close enclosure descriptions with a parenthesis rule):
        say ")";

    The last for printing an enclosure preposition rule (this is the default printing an enclosure preposition rule):
        if the described enclosure is a container or the described enclosure is a room:
            say "in ";
        otherwise if the described enclosure is a supporter:
            say "on ";
        otherwise:
            say "in ".

    To say rdh the (obj - an object): say "[the obj]".
    To say Rdh the (obj - an object): say "[The obj]".
        
    The last for describing an enclosure rule (this is the default describing an enclosure rule):
        say "[rdh the described enclosure]".