French

version 9/110414 by Eric Forgeot

  • Home page
  • Beginning
  • Previous
  • Next



  • Section 3 - French I7 replacements

    The you-can-also-see rule is not listed in any rulebook.

    For printing the locale description (this is the French-you-can-also-see rule):
        let the domain be the parameter-object;
        let the mentionable count be 0;
        repeat with item running through things:
            now the item is not marked for listing;
        repeat through the Table of Locale Priorities:
            [say "[notable-object entry] - [locale description priority entry].";]
            if the locale description priority entry is greater than 0,
                now the notable-object entry is marked for listing;
            increase the mentionable count by 1;
        if the mentionable count is greater than 0:
            repeat with item running through things:
                if the item is mentioned:
                    now the item is not marked for listing;
            begin the listing nondescript items activity with the domain;
            if the number of marked for listing things is 0:
                abandon the listing nondescript items activity with the domain;
            otherwise:
                if handling the listing nondescript items activity:
                    if the domain is a room:
                        if the domain is the location, say "[personne du joueur en capital] ";
                        otherwise say "Dans [the domain] [personne du joueur] ";
                    otherwise if the domain is a supporter:
                        say "Sur [the domain] [personne du joueur] ";
                    otherwise if the domain is an animal:
                        say "Sur [the domain] [personne du joueur] ";
                    otherwise:
                        say "Dans [the domain] [personne du joueur] ";
                    say "[verbe pouvoir du joueur] [if the locale paragraph count is greater than 0]aussi [end if]voir ";
                    let the common holder be nothing;
                    let contents form of list be true;
                    repeat with list item running through marked for listing things:
                        if the holder of the list item is not the common holder:
                            if the common holder is nothing,
                                now the common holder is the holder of the list item;
                            otherwise now contents form of list is false;
                        if the list item is mentioned, now the list item is not marked for listing;
                    filter list recursion to unmentioned things;
                    if contents form of list is true and the common holder is not nothing,
                        list the contents of the common holder, as a sentence, including contents,
                            giving brief inventory information, tersely, not listing
                            concealed items, listing marked items only;
                    otherwise say "[a list of marked for listing things including contents]";
                    [if the domain is the location, say " ici";] [supprimé de la version française car un peu lourd...]
                    say ".[paragraph break]";
                    unfilter list recursion;
                end the listing nondescript items activity with the domain;
        continue the activity.

    The use initial appearance in room descriptions rule is not listed in any rulebook.

    For printing a locale paragraph about a thing (called the item)
        (this is the French use initial appearance in room descriptions rule):
        if the item is not mentioned:
            if the item provides the property initial appearance and the
                item is not handled and the initial appearance of the item is
                not "":
                increase the locale paragraph count by 1;
                say "[initial appearance of the item]";
                say "[paragraph break]";
                if a locale-supportable thing is on the item:
                    repeat with possibility running through things on the item:
                        now the possibility is marked for listing;
                        if the possibility is mentioned:
                            now the possibility is not marked for listing;
                    say "Sur [the item] ";
                    list the contents of the item, as a sentence, including contents,
                        giving brief inventory information, tersely, not listing
                        concealed items, prefacing with is/are, listing marked items only;
                    say ".[paragraph break]";
                now the item is mentioned;
        continue the activity.

    The describe what's on scenery supporters in room descriptions rule is not listed in any rulebook.

    For printing a locale paragraph about a thing (called the item)
        (this is the French describe what's on scenery supporters in room descriptions rule):
        if the item is not undescribed and the item is scenery and the item does not enclose the player:
            if a locale-supportable thing is on the item:
                set pronouns from the item;
                repeat with possibility running through things on the item:
                    now the possibility is marked for listing;
                    if the possibility is mentioned:
                        now the possibility is not marked for listing;
                increase the locale paragraph count by 1;
                say "Sur [the item] ";
                list the contents of the item, as a sentence, including contents,
                    giving brief inventory information, tersely, not listing
                    concealed items, prefacing with is/are, listing marked items only;
                say ".[paragraph break]";
        continue the activity.


    The print the final question rule is not listed in any rulebook.
    The French print the final question rule is listed in before handling the final question.
    This is the French print the final question rule:
        let named options count be 0;
        repeat through the Table of French Final Question Options:
            if the only if victorious entry is false or the story has ended finally:
                if there is a final response rule entry
                    or the final response activity entry [activity] is not empty:
                    if there is a final question wording entry, increase named options count by 1;
        if the named options count is less than 1, abide by the immediately quit rule;
        say "Voulez-vous ";
        repeat through the Table of French Final Question Options:
            if the only if victorious entry is false or the story has ended finally:
                if there is a final response rule entry
                    or the final response activity entry [activity] is not empty:
                    if there is a final question wording entry:
                        say final question wording entry;
                        decrease named options count by 1;
                        if the named options count is 0:
                            say "?[line break]";
                        otherwise if the named options count is 1:
                            if the serial comma option is active, say ",";
                            say " ou ";
                        otherwise:
                            say ", ";

    The standard respond to final question rule is not listed in any rulebook.
    The French standard respond to final question rule is listed last in for handling the final question.
    This is the French standard respond to final question rule:
        repeat through the Table of French Final Question Options:
            if the only if victorious entry is false or the story has ended finally:
                if there is a final response rule entry
                    or the final response activity entry [activity] is not empty:
                    if the player's command matches the topic entry:
                        if there is a final response rule entry, abide by final response rule entry;
                        otherwise carry out the final response activity entry activity;
                        rule succeeds;
        issue miscellaneous library message number 8.