Section 1 - Introductions for objects

A thing can be as-yet-unknown or introduced. A thing is usually as-yet-unknown.
A thing has some text called the introduction. The introduction of a thing is usually "".

Definition: a thing is introduceable if it is as-yet-unknown and its introduction is not "" and it is visible.
    
To introduce (special-target - an object):
    now the special-target is introduced;
    say "[introduction of the special-target]".

Rule for writing a paragraph about an introduceable thing (called special-target) (this is the introduce unknowns rule):
    now the special-target is mentioned;
    introduce the special-target;
    now the special-target is holding-paragraph-break.

A thing can be holding-paragraph-break or paragraph-complete.
    
After writing a paragraph about something (called original-target) which segue-suggests an introduceable thing (called special-target) (this is the connect related paragraphs rule):
    segue from original-target to special-target;
    if the special-target is not introduced,
        carry out the writing a paragraph about activity with the special-target;
    otherwise say fake-paragraph-break;
    now the original-target is paragraph-complete;
    now the special-target is paragraph-complete.

After writing a paragraph about something (called special-target) which is holding-paragraph-break:
    now the special-target is paragraph-complete;
    say fake-paragraph-break.

fake-paragraph-break is some text that varies. fake-paragraph-break is "[line break]".
    
segue-suggesting relates various things to various things. The verb to segue-suggest (it segue-suggests, they segue-suggest, it segue-suggested, it is segue-suggested, it is segue-suggesting) implies the segue-suggesting relation.

When play begins (this is the initialize segues rule):
    repeat through the Table of Segues
    begin;
        now first entry segue-suggests second entry;
    end repeat.

To segue from (original item - a thing) to (next item - a thing):
    repeat through Table of Segues
    begin;
        if original item is the first entry
        begin;
            if the next item is the second entry
            begin;
                say " [segue entry]";
                blank out the whole row;
                rule succeeds;
            end if;
        end if;
    end repeat.

To say override intro/introduction of/for (N - a thing):
    now N is mentioned;
    now N is introduced.
    
Table of Segues

first	second	segue
a thing	a thing	some text