Armed

version 3 by David Ratliff

  • Home page
  • Beginning
  • Previous
  • Next



  • Section 4 - Stabbing

    Stabbing it with is an action applying to two visible things. Understand "stab [something] with [something]" as stabbing it with. The stabbing it with action has a number called the damage dealt.

    Setting action variables for an actor stabbing something (called target) with something (called pigsticker):
    if the target is a person begin;
    if the pigsticker is a blade begin;
    change the damage dealt to a random number between 10 and the maximum damage of the second noun;
    end if;
    end if.

    Check stabbing something (called the target) with something (called the pigsticker) (this is the you must have a blade to stab rule):
        if the player does not carry a blade begin;
            say "You need a bladed weapon to stab anything.";
            stop the action;
        end if.

    Check stabbing something (called the target) with something (called the pigsticker) (this is the you can only stab with a blade rule):
        if the second noun is not a blade begin;
            say "And I suppose you cut your meat with a spoon? Why not try something with a blade?";
            stop the action;
        end if.

    Check stabbing something (called the target) with something (called the pigsticker) (this is the you can't stab something with itself rule):
        if the target is the pigsticker begin;
            say "You try to break the blade so that. . . Wait, you can't stab [the pigsticker] with itself!";
            stop the action;
        end if.

    Check stabbing something (called the target) with something (called the pigsticker) (this is the harikari rule):
        if the target is the player, end the game saying "You have commited suicide!".

    Carry out an actor stabbing something (called the target) with something (this is the standard carry out stabbing rule):
        if the target is a person begin;
            decrease the present health of the target by the damage dealt;
            if the target is not the player begin;
                if the target is docile, change the target to hostile;
            end if;
        end if.

    Report stabbing something (called the target) with something(called the pigsticker) (this is the report stabbing people rule):
        if the target is a person begin;
            if the target is dead begin;
                say "With one final thrust of your [pigsticker], [the target] drops to the ground, dead." instead;
            end if;
        say "You stab [the target] with your [the pigsticker]. [The target] yells out in pain. ([The target][apostrophe]s health: [present health of the target])[line break]";
        end if.

    Report stabbing something (called the target) with something(called the pigsticker) (this is the report stabbing non-people rule):
        if the target is not a person, say "You stab [the target] with your [the pigsticker]. Well, I hope that made you feel better. Hopefully stabbing [the target] won[apostrophe]t attract any unwanted attention.".

    Check someone stabbing something (called the target) with something (called the pigsticker) (this is the others must have a blade to stab rule):
        if the person asked does not carry a blade begin;
            say "[The person asked] says 'With what? I don't have a bladed weapon.'";
            stop the action;
        end if.

    Check someone stabbing something (called the target) with something (called the pigsticker) (this is the others can only stab with a blade rule):
        if the second noun is not a blade begin;
            say "[The person asked] says '[The second noun] would need to be some kind of bladed weapon for that to work.'";
            stop the action;
        end if.

    Check someone stabbing something (called the target) with something (called the pigsticker) (this is the others can't stab something with itself rule):
        if the target is the pigsticker begin;
            say "[The person asked] says 'I can hardly stab [the pigsticker] with itself!'";
            stop the action;
        end if.

    Check someone stabbing something (called the target) with something (called the pigsticker) (this is the other people harikari rule):
        if the target is the person asked, say "[The person asked] says 'I refuse to commit suicide!'" instead.

    Report someone stabbing something (called the target) with something(called the pigsticker) (this is the report another stabbing a person rule):
        if the target is a person begin;
            if the target is dead begin;
                say "[The person asked] stabs [the target], who drops to the ground, dead." instead;
            end if;
            if the target is not the player begin;
                say "[The person asked] thrust the [the pigsticker] into [the target], who screams out in pain. ([The target][apostrophe]s health: [present health of the target])[line break]";
            end if;
            if the target is the player begin;
                say "[The person asked] stabs you! (Health: [present health of the player])[line break]";
            end if;
        end if.

    Report someone stabbing something (called the target) with something(called the pigsticker) (this is the report another stabbing a non-person rule):
        if the target is not a person, say "In a seemingly random act of violence, [the person asked] stabs [the target].".

    After someone stabbing something (called the target) with something (called the pigsticker) (this is the stabbed to death rule):
        if the target is the player begin;
            if the player is dead begin;
                say "[The person asked] stabs you with [the pigsticker], and you drop to the ground, dead.";
                end the game in death;
            end if;
        end if;
    continue the action.